---
name: "activateAddons"
type: command
status: ok
groups: ["Mods and Addons"]
arma3_since: "0.50"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/activateAddons
revid: 370473
updated: 2024-12-16T18:10:00Z
---

# activateAddons

*Command · Mods and Addons · Arma 3 v0.50 · introduced in Operation Flashpoint: Elite v1.00*

## Description

Activates the listed addons.

## Syntax

```sqf
activateAddons addonsList
```

**Parameters:**

- `addonsList`: [Array](../topics/Array.md) of [String](../topics/String.md)s

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
activateAddons ["BISOFP"];
```

## See also

[unitAddons](../commands/unitAddons.md) · [activatedAddons](../commands/activatedAddons.md)

## Community notes

**WGL.Q** — 2009-01-21

Be aware that addon's string is the `CfgPatches` class of the desired addon to preload.

---

**UNN** — 2009-05-10

This command will activate addons that are referenced via scripts but not included in a missions required addons section. If executed from a configs init event with the [call](../commands/call.md) command, it will effectively override a missions required addons, preventing them from being activated (Appears to only happen in multi player).
To activate the passed addons along with those defined in the mission.sqm, execute the command from a configs init event using [spawn](../commands/spawn.md) or [execVM](../commands/execVM.md).

---

**Sa-Matra** — 2022-07-03

Here is a handy function to call before you do [createVehicle](../commands/createVehicle.md) or other create* command during missing init scripts, which should activate missing addons without having to worry about re-adding previously added addons.

```sqf
fnc_prepareClassAddons = {
    private _class = toLower _this;

    // To avoid double checks
    if(isNil"var_addonCheckedClasses") then {var_addonCheckedClasses = createHashMap;};
    if(_class in var_addonCheckedClasses) exitWith {};

    // Finding missing addons
    private _needed = unitAddons _class apply {toLower _x};
    private _active = activatedAddons;
    private _missing = _needed - (_needed arrayIntersect _active);
    if(count _missing > 0) then {
        // Adding everything again, engine will figure it out itself
        _active append _missing;
        activateAddons _active;
    };

    var_addonCheckedClasses set [_class, _needed];
};
```

Usage would be `"Land_BurntGarbage_01_F" call fnc_prepareClassAddons`.

<sub>Source: [BI Community Wiki — activateAddons](https://community.bistudio.com/wiki/activateAddons) (revision 370473).</sub>