---
name: "addForce"
type: command
status: ok
groups: ["PhysX"]
arma3_since: "1.72"
locality: {"argument": "global", "effect": "global", "server_exec": false}
source: https://community.bistudio.com/wiki/addForce
revid: 377384
updated: 2026-01-02T06:43:53Z
---

# addForce

*Command · PhysX · Arma 3 v1.72*

Locality: arguments **global** · effect **global**

## Description

Applies given force for one frame (essentially an impulse) to unit or given PhysX object at given position.

> [!NOTE]
> For more information see [NVIDIA docs](http://docs.nvidia.com/gameworks/content/gameworkslibrary/physx/apireference/files/classPxRigidBody.html).

## Syntax

```sqf
object addForce [force, position, setUnconscious]
```

**Parameters:**

- `object`: [Object](../topics/Object.md) - PhysX object or Arma 3 v2.04Local Argument unit, in which case the unit must be local and will be [set unconscious](../commands/setUnconscious.md)
- `force`: [Vector3D](../topics/Vector3D.md) - force vector in **world** space; force is expressed in
  [newton-seconds](https://en.wikipedia.org/wiki/Newton-second) (used by [PxForceMode::eIMPULSE](https://docs.nvidia.com/gameworks/content/gameworkslibrary/physx/apireference/files/structPxForceMode.html))
- `position`: [PositionRelative](../topics/Position.md#positionrelative) - relative to object
- `setUnconscious`: [Boolean](../topics/Boolean.md) - (Optional, default [true](../commands/true.md)) only applies to "CAManBase" *object*; set to [false](../commands/false.md) to keep the person conscious *(since arma3 2.18)*

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

Apply force [0,1000,0] defined in world space (not factoring object actual positioning) to object position [1,0,0]:

```sqf
_object addForce [[0,1000,0], [1,0,0]];
```

### Example 2

Apply force [0,1000,0] defined in model space (relative to object) to object position [1,0,0]:

```sqf
_object addForce [_object vectorModelToWorld [0,1000,0], [1,0,0]];
```

### Example 3

Can be used on units since Arma 3 v2.04:

```sqf
if (local bob) then
{
    0 spawn 
    {
        bob addForce [bob vectorModelToWorld [0,-200,0], bob selectionPosition "rightfoot"];
        sleep 5;
        bob setUnconscious false;
    };
};
```

### Example 4

```sqf
player addForce [player vectorModelToWorld [0, -1, 0], [0, 1, 0], false]; // not unconscious
```

## See also

[addTorque](../commands/addTorque.md) · [awake](../commands/awake.md) · [isAwake](../commands/isAwake.md) · [vectorModelToWorld](../commands/vectorModelToWorld.md) · [vectorModelToWorldVisual](../commands/vectorModelToWorldVisual.md) · [selectionPosition](../commands/selectionPosition.md) · [disableBrakes](../commands/disableBrakes.md) · [brakesDisabled](../commands/brakesDisabled.md)

<sub>Source: [BI Community Wiki — addForce](https://community.bistudio.com/wiki/addForce) (revision 377384).</sub>