---
name: "break"
type: command
status: ok
groups: ["Program Flow"]
arma3_since: "2.02"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/break
revid: 370194
updated: 2024-11-06T11:55:55Z
---

# break

*Command · Program Flow · Arma 3 v2.02*

## Description

Skips all loop iterations ([for](../commands/for.md), [forEach](../commands/forEach.md), [while](../commands/while.md), [findIf](../commands/findIf.md) etc).

## Syntax

```sqf
break
```

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
// prints 0, 1 and then exits
for "_i" from 0 to 3 do
{
    if (_i == 2) then { break };
    systemChat str _i;
};
```

### Example 2

```sqf
private _moneyHolder = objNull;
{
    if ("Money_roll" in items _x) then
    {
        _moneyHolder = _x;
        break;
    };
} forEach units group player;

if (isNull _moneyHolder) then
{
    hint "We have to find this money.";
}
else
{
    hint format ["%1 has the money!", name _moneyHolder];
};
```

### Example 3

```sqf
0 spawn
{
    private _value = 0;

    while { _value < 10 } do
    {
        if (_value == 8) then
        {
            break; // 8 and 9 will never be printed
        };

        systemChat str _value ;
        _value = _value + 1;
    };
};
```

## See also

[continueWith](../commands/continueWith.md) · [continue](../commands/continue.md) · [breakWith](../commands/breakWith.md) · [breakOut](../commands/breakOut.md)

<sub>Source: [BI Community Wiki — break](https://community.bistudio.com/wiki/break) (revision 370194).</sub>