---
name: "createVehicleCrew"
type: command
status: ok
groups: ["Object Manipulation"]
arma3_since: "0.76"
locality: {"argument": "global", "effect": "global", "server_exec": false}
source: https://community.bistudio.com/wiki/createVehicleCrew
revid: 369241
updated: 2024-09-03T10:35:01Z
---

# createVehicleCrew

*Command · Object Manipulation · Arma 3 v0.76*

Locality: arguments **global** · effect **global**

## Description

Creates vehicle crew corresponding to the provided vehicle's [faction](../commands/faction.md). If the vehicle is already occupied, the command will only create missing crew in the existing vehicle's group.

To find out which crew will be created, use [BIS_fnc_vehicleCrewTurrets](../functions/BIS_fnc_vehicleCrewTurrets.md).

|  |  |  |
|---|---|---|
| + This command: | Does | Does not |
| - Arma 3 v1.26 create a group if one is needed (otherwise uses `group _vehicle`)<br>- create a driver if the vehicle needs one (`hasDriver = 1;` in config)<br>- create [all non-FFV turrets](../commands/allTurrets.md) gunners (if the turret needs one - config {`hasGunner` without `dontCreateAI`)<br>- create crew with **[rank](../commands/rank.md)s** - with the driver as `"LIEUTENANT"` and all turret units as `"SERGEANT"`, unlike a crewed vehicle placed in Eden Editor where all units are `"PRIVATE"`. | - [add vehicle](../commands/addVehicle.md) to the group, unlike a crewed vehicle placed in Eden Editor. See [BIS_fnc_spawnVehicle](../functions/BIS_fnc_spawnVehicle.md) to spawn a crew-full vehicle with group addition<br>- create cargo units. |  |

## Syntax

### Syntax 1

```sqf
createVehicleCrew vehicle
```

**Parameters:**

- `vehicle`: [Object](../topics/Object.md) - vehicle to populate with crew

**Returns:** [Group](../topics/Group.md) - the group of the created crew (since Arma 3 v1.94; before that returned [Nothing](../topics/Nothing.md))

### Syntax 2

*since arma3 2.14*

```sqf
group createVehicleCrew vehicle
```

**Parameters:**

- `group`: [Group](../topics/Group.md) - group to put crew in
- `vehicle`: [Object](../topics/Object.md) - vehicle to populate with crew

**Returns:** [Group](../topics/Group.md) - the group of the created crew or [grpNull](../commands/grpNull.md)

### Syntax 3

*since arma3 2.14*

```sqf
side createVehicleCrew vehicle
```

**Parameters:**

- `side`: [Side](../topics/Side.md) - side to create crew on
- `vehicle`: [Object](../topics/Object.md) - vehicle to populate with crew

**Returns:** [Group](../topics/Group.md) - the group of the created crew or [grpNull](../commands/grpNull.md)

## Examples

### Example 1

```sqf
_veh = createVehicle ["B_MRAP_01_F", getMarkerPos "createVeh", [], 0, "NONE"];
createVehicleCrew _veh;
```

### Example 2

```sqf
_veh = createVehicle ["O_MRAP_02_hmg_F", position player, [], 0, "NONE"];
createVehicleCrew _veh;
{
    diag_log [_x, faction _x, side _x, side group _x];
} forEach crew _veh;

// [O Alpha 1-1:1,"OPF_F",EAST,EAST]
// [O Alpha 1-1:2,"OPF_F",EAST,EAST]
```

## Multiplayer

This command seems to be Local Argument with UAVs.

## See also

[deleteVehicleCrew](../commands/deleteVehicleCrew.md) · [moveInDriver](../commands/moveInDriver.md) · [moveInGunner](../commands/moveInGunner.md) · [moveInCommander](../commands/moveInCommander.md) · [moveInTurret](../commands/moveInTurret.md) · [moveInCargo](../commands/moveInCargo.md) · [BIS_fnc_spawnVehicle](../functions/BIS_fnc_spawnVehicle.md)

## Community notes

**SilentSpike** — 2014-08-20

As of Arma 3 v1.26 the command will work on non-empty vehicles. If any of the crew defined in config are missing they will be added.

---

**DrPastah** — 2015-12-22

[createVehicleCrew](../commands/createVehicleCrew.md) does not work with Transport Unload waypoints for helicopters. You need to spawn the pilots separately and then get them into the helicopter in order to get Transport Unload waypoints to work.

---

**AgentRev** — 2017-06-02

The particular seats to which units are added depend on the `dontCreateAI` property, the `hasDriver` property of the base class, and the `hasGunner` propery of turret classes.

For instance, the following snippet calculates how many seats will be occupied by the created crew:

```sqf
private _vehCfg = configFile >> "CfgVehicles" >> typeOf _vehicle;
private _crewCount = {
    round getNumber (_x >> "dontCreateAI") < 1 && 
    ((_x == _vehCfg && { round getNumber (_x >> "hasDriver") > 0 }) ||
    (_x != _vehCfg && { round getNumber (_x >> "hasGunner") > 0 }))
} count ([_vehicle, configNull] call BIS_fnc_getTurrets);
```

Also, I've written a function to create a UAV crew for a specific side: https://gist.github.com/AgentRev/cb25d30e464f2239b6cee51fa0110c78

<sub>Source: [BI Community Wiki — createVehicleCrew](https://community.bistudio.com/wiki/createVehicleCrew) (revision 369241).</sub>