---
name: "ctrlSetScrollValues"
type: command
status: ok
groups: ["GUI Control"]
arma3_since: "2.00"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/ctrlSetScrollValues
revid: 338941
updated: 2023-04-17T15:45:43Z
---

# ctrlSetScrollValues

*Command · GUI Control · Arma 3 v2.00*

## Description

Sets scroll values for current scrollbars in range 0..1 for the following controls:
- CT_CONTROLS_TABLE
- CT_CONTROLS_GROUP
- CT_TREE
- CT_LISTBOX
- CT_COMBO
- CT_XCOMBO
- CT_LISTNBOX
- CT_LISTNBOX_CHECKABLE

## Syntax

```sqf
control ctrlSetScrollValues [vScrollValue, hScrollValue]
```

**Parameters:**

- `control`: [Control](../topics/Control.md)
- `vScrollValue`: [Number](../topics/Number.md) - vertical scroll value in 0..1 range. -1 to skip
- `hScrollValue`: [Number](../topics/Number.md) - horizontal scroll value in 0..1 range. -1 to skip

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
_ctrlGrp ctrlSetScrollValues [-1, 0.5];
```

### Example 2

```sqf
// ControlsGroup
private _disp = findDisplay 46 createDisplay "RscDisplayEmpty";
private _ctrlGrp = _disp ctrlCreate ["RscControlsGroup", -1];
private _ctrl = _disp ctrlCreate ["RscTree", -1, _ctrlGrp];
_ctrl tvAdd [[], "Root"];
for "_i" from 1 to 25 do
{
    _ctrl tvAdd [[0], format ["Tree Item %1", _i]];
};
_ctrl ctrlSetPosition [0,0,0.3,1.2];
_ctrl ctrlCommit 0;
tvExpandAll _ctrl;
_ctrlGrp ctrlSetPosition [0,0,0.2,0.3];
_ctrlGrp ctrlCommit 0;
 
uiNamespace setVariable ["_ctrl", _ctrlGrp];
onEachFrame
{
    hintSilent str ctrlScrollValues (uiNamespace getVariable ["_ctrl", controlNull]);
};
0 spawn
{
    sleep 1;
    uiNamespace getVariable ["_ctrl", controlNull] ctrlSetScrollValues [0.3, -1];
    sleep 1;
    uiNamespace getVariable ["_ctrl", controlNull] ctrlSetScrollValues [-1, 0.3];
    sleep 1;
    uiNamespace getVariable ["_ctrl", controlNull] ctrlSetScrollValues [0.7, -1];
    sleep 1;
    uiNamespace getVariable ["_ctrl", controlNull] ctrlSetScrollValues [-1, 0.7];
};
```

## See also

[ctrlScrollValues](../commands/ctrlScrollValues.md) · [sliderSetPosition](../commands/sliderSetPosition.md) · [progressSetPosition](../commands/progressSetPosition.md)

<sub>Source: [BI Community Wiki — ctrlSetScrollValues](https://community.bistudio.com/wiki/ctrlSetScrollValues) (revision 338941).</sub>