---
name: "fullCrew"
type: command
status: ok
groups: ["Object Manipulation"]
arma3_since: "1.34"
locality: {"argument": "global", "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/fullCrew
revid: 377160
updated: 2026-01-01T10:40:32Z
---

# fullCrew

*Command · Object Manipulation · Arma 3 v1.34*

Locality: arguments **global**

## Description

Returns an array with all crew inside given vehicle, with or without empty seats.

> [!IMPORTANT]
> With the introduction of person turrets (FFV), the returned *cargoIndex* works with [moveInCargo](../commands/moveInCargo.md) but does not with [action](../commands/action.md)s such as "GetInCargo" and "MoveToCargo".
> To find out indexes for actions, use the "cargo" filter (See [#Example 3](../commands/fullCrew.md#example-3)).

## Syntax

### Syntax 1

```sqf
fullCrew vehicle
```

**Parameters:**

- `vehicle`: [Object](../topics/Object.md)

**Returns:** [Array](../topics/Array.md) - list of arrays in format [unit, role, cargoIndex, turretPath, personTurret, assignedUnit, positionName]:
- unit: [Object](../topics/Object.md)
- role: [String](../topics/String.md) - not always lowercase before Arma 3 v2.04
- cargoIndex: [Number](../topics/Number.md)
- turretPath: Turret Path
- personTurret: [Boolean](../topics/Boolean.md)
- Arma 3 v2.12 assignedUnit: [Object](../topics/Object.md) - see *assignAsXXX* commands, [assignAsDriver](../commands/assignAsDriver.md) for example
- Arma 3 v2.12 positionName: [String](../topics/String.md) - un[localize](../commands/localize.md)d entry for turret's `gunnerName`, for example "$STR_A3_TURRETS_CARGOTURRET_R2"

### Syntax 2

```sqf
fullCrew [vehicle, type, includeEmpty]
```

**Parameters:**

- `vehicle`: [Object](../topics/Object.md)
- `type`: [String](../topics/String.md) - role filter (case-insensitive). An invalid value (e.g "") will return all positions. Available values:
  - "driver"
  - "commander"
  - "gunner"
  - "turret"
  - "cargo"
- `includeEmpty`: [Boolean](../topics/Boolean.md) - (Optional, default [false](../commands/false.md)) include empty crew seats *(since arma3 1.56)*

**Returns:** [Array](../topics/Array.md) - list of arrays in format [unit, role, cargoIndex, turretPath, personTurret, assignedUnit, positionName]:
- unit: [Object](../topics/Object.md)
- role: [String](../topics/String.md) - not always lowercase before Arma 3 v2.04
- cargoIndex: [Number](../topics/Number.md)
- turretPath: Turret Path
- personTurret: [Boolean](../topics/Boolean.md)
- Arma 3 v2.12 assignedUnit: [Object](../topics/Object.md) - see *assignAsXXX* commands, [assignAsDriver](../commands/assignAsDriver.md) for example
- Arma 3 v2.12 positionName: [String](../topics/String.md) - un[localize](../commands/localize.md)d entry for turret's `gunnerName`, for example "$STR_A3_TURRETS_CARGOTURRET_R2"

## Examples

### Example 1

```sqf
_list = fullCrew vehicle player;
/*
    returns for example (on an armed WY-55 Hellcat):
    [
        [R Alpha 1-1:1, "driver", -1, [], false, R Alpha 1-1:1, "$STR_POSITION_DRIVER"],
        [R Alpha 1-1:2, "turret", -1, [0], false, R Alpha 1-1:2, "$STR_A3_COPILOT"]
    ]
*/
```

### Example 2

```sqf
_list = fullCrew [vehicle player, "turret"];
/*
    returns for example (on an armed WY-55 Hellcat):
    [
        [R Alpha 1-1:2, "turret", -1, [0], false, R Alpha 1-1:2, "$STR_A3_COPILOT"]
    ]
*/
```

### Example 3

```sqf
private _actionCompatibleCargoIndexes = fullCrew [heli, "cargo", true];
/*
    returns for example (on an empty armed WY-55 Hellcat):
    [
        [objNull, "cargo", 2, [], false, objNull, "$STR_GETIN_POS_PASSENGER"],
        [objNull, "cargo", 3, [], false, objNull, "$STR_GETIN_POS_PASSENGER"],
        [objNull, "cargo", 4, [], false, objNull, "$STR_GETIN_POS_PASSENGER"],
        [objNull, "cargo", 5, [], false, objNull, "$STR_GETIN_POS_PASSENGER"]
    ]
    using the element's index is compatible with action cargo commands - see below
*/

// the following commands will put the player in the same seat:
player moveInCargo [heli, 2];
player action ["GetInCargo", heli, 0];
```

## See also

[crew](../commands/crew.md) · [createVehicleCrew](../commands/createVehicleCrew.md) · [assignedVehicleRole](../commands/assignedVehicleRole.md) · [allTurrets](../commands/allTurrets.md) · [emptyPositions](../commands/emptyPositions.md)

<sub>Source: [BI Community Wiki — fullCrew](https://community.bistudio.com/wiki/fullCrew) (revision 377160).</sub>