---
name: "hint"
type: command
status: ok
groups: ["Interaction", "Structured Text", "Strings"]
arma3_since: "0.50"
locality: {"argument": null, "effect": "local", "server_exec": false}
source: https://community.bistudio.com/wiki/hint
revid: 376426
updated: 2025-10-12T22:43:43Z
---

# hint

*Command · Interaction, Structured Text, Strings · Arma 3 v0.50 · introduced in Operation Flashpoint v1.00*

Locality: effect **local**

## Description

Outputs a hint message to the right of the screen (left of the screen in Operation Flashpoint) with a sound (except in Armed Assault).
To split message in multiple lines either use [Structured Text](../topics/Structured_Text.md) or `\n` (in lower case).

> [!NOTE]
> **Armed Assault:** Armed Assault hints are silent. For later titles, see [hintSilent](../commands/hintSilent.md).

## Syntax

```sqf
hint message
```

**Parameters:**

- `message`: [String](../topics/String.md) or [Structured Text](../topics/Structured_Text.md) - the message to display.

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
// outputs the following:
// Press W to move forward.
// Press S to move backwards.
hint "Press W to move forward.\nPress S to move backwards."
```

### Example 2

```sqf
hint format ["Hello, %1!", name player];
```

### Example 3

```sqf
hint str count allPlayers;
sleep 10;
hintSilent ""; // hides the previous hint display
```

### Example 4

```sqf
hint parseText "<t size='2.0'>Large text</t>"; // displays text twice as large as the default one
```

### Example 5

```sqf
_txt = text "Red text, right align";
_txt setAttributes ["color", "#FF0000", "align", "right"];
hint composeText [_txt];
```

## Problems

Operation Flashpoint v1.00 Armed Assault v1.00 Arma 2 v1.00 Hint messages that exceed the screen may lead to crashes.

Arma 3 v1.00 The game would not crash but suffer FPS drop / temporary freezing.

## See also

[hintC](../commands/hintC.md) · [hintCadet](../commands/hintCadet.md) · [hintSilent](../commands/hintSilent.md) · [diag_log](../commands/diag_log.md)

## Community notes

**DreadedEntity** — 2014-10-20

Be careful when using hints to visualize the effects of commands using the Debug Console. Hint can accept an undefined variable and neither the error nor the hint is shown, the command simply fails. Also notice how the hint command should be `hint str _i;`:

```sqf
for "_i" from 0 to 50 do
{
    hint _i;
};
```

**tested in A3 1.32.127785**

In a script, an "undefined variable" error will be shown as expected.

---

**DreadedEntity** — 2014-10-21

Contrary to previous games, Arma 3 will happily display hints that far exceed screen space.

However, as hints get longer, FPS suffers tremendously.

**tested in Debug Console, A3 1.32.127785 with the following:**

```sqf
hint str ((nearestObjects [player, ["BUILDING"],  100]) - [player]); 0 spawn { sleep 5; systemChat str diag_fps; };
sleep 10;
hint str ((nearestObjects [player, ["BUILDING"], 1000]) - [player]); 0 spawn { sleep 5; systemChat str diag_fps; };
```

Results were: **59.7015** and **5.17297**, respectively. Drawing a hint even longer than this, such as [nearestObjects](../commands/nearestObjects.md) with a radius of 10,000 or 100,000 reduces your FPS so much Arma 3 **appears** to crash, though it doesn't.

Unrelated: Hints will stay on screen for 30 seconds, then fade away over the course of 5 seconds. **Tested with: A3 1.32.127785**

---

**DreadedEntity** — 2015-02-17

An open dialog will pause the 30-second hint fade timer.
**(A3 1.38.128937)**

---

**Feint** — 2017-03-25

The [hint](../commands/hint.md) sound is audible only when you have the music volume turned up above 0 in the audio settings.
Otherwise, it seems to act the same as [hintSilent](../commands/hintSilent.md).

This is important because if you are running a [hint](../commands/hint.md) that fires at 30 fps or more, the [hint](../commands/hint.md) will slow down machines that have the music volume turned up but won't slow down machines that have the music volume turned off.

Best practice is to use [hint](../commands/hint.md) for an alert to the player and use [hintSilent](../commands/hintSilent.md) for a makeshift display of data to the player that is updated fairly often.

<sub>Source: [BI Community Wiki — hint](https://community.bistudio.com/wiki/hint) (revision 376426).</sub>