---
name: "hintC"
type: command
status: ok
groups: ["Interaction", "Structured Text", "Strings"]
arma3_since: "0.50"
locality: {"argument": null, "effect": "local", "server_exec": false}
source: https://community.bistudio.com/wiki/hintC
revid: 369068
updated: 2024-09-02T20:24:57Z
---

# hintC

*Command · Interaction, Structured Text, Strings · Arma 3 v0.50 · introduced in Operation Flashpoint v1.00*

Locality: effect **local**

## Description

Displays a very basic message dialog in the center of the screen. Player control is taken away until "Continue" is pressed. The message dialog can be dragged around on the screen. After "Continue" has been pressed, the content of the [hintC](../commands/hintC.md) is repeated in a normal [hint](../commands/hint.md).

> [!NOTE]
> In Singleplayer, the game is paused while the message dialog is visible.

## Syntax

### Syntax 1

```sqf
hintC message
```

**Parameters:**

- `message`: [String](../topics/String.md)

**Returns:** [Nothing](../topics/Nothing.md)

### Syntax 2

```sqf
title hintC message
```

**Parameters:**

- `title`: [String](../topics/String.md) - message title
- `message`: [String](../topics/String.md), [Structured Text](../topics/Structured_Text.md), [Array](../topics/Array.md) of [String](../topics/String.md)s or [Array](../topics/Array.md) of [Structured Text](../topics/Structured_Text.md)

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
hintC "Press W to move forward";
```

### Example 2

Same as the above in Arma 3 but without second [hint](../commands/hint.md) displayed:

```sqf
hintC "Press W to move forward";
hintC_EH = findDisplay 57 displayAddEventHandler ["Unload", {
    _this spawn {
        _this select 0 displayRemoveEventHandler ["Unload", hintC_EH];
        hintSilent "";
    };
}];
```

### Example 3

```sqf
"Instructions" hintC [
    "Press W to move forward.",
    "Press S to move backwards.",
    "Use the mouse to turn right or left.",
    "Press V for weapon sights."
];
```

### Example 4

Same as the above in Arma 3 but without second [hint](../commands/hint.md) displayed:

```sqf
"Instructions" hintC [
    "Press W to move forward.",
    "Press S to move backwards.",
    "Use the mouse to turn right or left.",
    "Press V for weapon sights."
];
hintC_EH = findDisplay 72 displayAddEventHandler ["Unload", {
    _this spawn {
        _this select 0 displayRemoveEventHandler ["Unload", hintC_EH];
        hintSilent "";
    };
}];
```

### Example 5

```sqf
private _separator = parseText "<br/>------------------------<br/>";
private _image = "\ca\ui\textures\aus_flag.paa";
private _message = composeText [image _image, "Heading Text", _separator, "Content"];
"" hintC _message;
```

## See also

[hint](../commands/hint.md) · [hintCadet](../commands/hintCadet.md) · [hintSilent](../commands/hintSilent.md) · [BIS_fnc_guiMessage](../functions/BIS_fnc_guiMessage.md)

## Community notes

**Str** — 2006-07-31

This command must be executed after mission start. If you place it into init.sqs or init field of some unit, it will not work. Just add a little delay (~0.001) and the place the command.

---

**Worldeater** — 2009-05-15

To display multiple messages after another you have to add a small delay in between. Otherwise only the first message will be displayed.

```sqf
hintC "foo"; sleep 0.1; hintC "bar"
```

Without a [sleep](../commands/sleep.md) statement [hintC](../commands/hintC.md) will not suspend the script it has been called from.

---

**Killzone_Kid** — 2015-03-19

"Titled" [hintC](../commands/hintC.md) uses `display #72` while "untitled" one uses `display #57`. If you are trying examples in Arma 3 debug console, add a little delay like this:

```sqf
0 spawn { sleep 0.5; /* your example code goes here*/ };
```

 or no [hintC](../commands/hintC.md) will be displayed.

<sub>Source: [BI Community Wiki — hintC](https://community.bistudio.com/wiki/hintC) (revision 369068).</sub>