---
name: "isTouchingGround"
type: command
status: ok
groups: ["Object Manipulation"]
arma3_since: "0.50"
locality: {"argument": "global", "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/isTouchingGround
revid: 376406
updated: 2025-10-11T00:58:13Z
---

# isTouchingGround

*Command · Object Manipulation · Arma 3 v0.50*

Locality: arguments **global**

## Description

Returns true if object is touching the ground.

## Syntax

```sqf
isTouchingGround object
```

**Parameters:**

- `object`: [Object](../topics/Object.md)

**Returns:** [Boolean](../topics/Boolean.md)

## Examples

### Example 1

```sqf
if (isTouchingGround player) then { hint "Terraferma!" };
```

### Example 2

A full "is safely parked" method for air, ground and water vehicles:

```sqf
// get if a vehicle is properly parked - covers e.g helicopter landed on a building, boat (beached or not) and underwater or not submarine
// return false on null, disabled or destroyed vehicle
private _isSafelyParked = {
    params [
        ["_vehicle", objNull, [objNull]],                // 0: OBJECT - vehicle - a null object returns false
        ["_altitudeTolerance", 0.1, [0]],                // 1: NUMBER - altitude tolerance - in metre
        ["_velocityTolerance", 0.01, [0]]                // 2: NUMBER - velocity tolerance - in km/h
    ];

    if (not canMove _vehicle) exitWith { false };        // returns false for null as well

    if (_vehicle isKindOf "Ship") then
    {
        // surfaceIsWater getPosASL _vehicle                        // a beached boat is fine
        velocity _vehicle params ["_velX", "_velY"];
        sqrt (_velX * _velX + _velY * _velY) < _velocityTolerance    // only 2D speed matters (think waves)
        && {
            getPosASLW _vehicle select 2 < _altitudeTolerance                // underwater submarines are OK
            || { getPos _vehicle select 2 < _altitudeTolerance }    // beached boat
        };
    }
    else
    {
        // over -a- ground and not over ocean
        (isTouchingGround _vehicle || {
            getPosASLW _vehicle select 2 >= _altitudeTolerance        // not in water
            && { getPos _vehicle select 2 < _altitudeTolerance }
        })
        && { vectorMagnitude velocity _vehicle * 3.6 < _velocityTolerance }
    }
};

objectParent player call _isSafelyParked;
```

## See also

[underwater](../commands/underwater.md)

## Community notes

**AgentRev** — 2014-06-01

If you are using this command as a validation method, it should not be the sole thing you are checking for, as the result is often inaccurate.
For example, it returns false for some helicopters when landed on the roof of certain buildings, and it always returns false for boats, even if they are beached.

---

**Demellion** — 2016-09-29

In addition to previous statement: That behaviour is true, simply because [isTouchingGround](../commands/isTouchingGround.md) applied to a player unit (or any unit) is frozen to a last state when unit enters vehicle.
To get proper return from this command you should go for units [vehicle](../commands/vehicle.md):

```sqf
_var = isTouchingGround player;                // unreliable
_var = isTouchingGround (vehicle player);    // pretty reliable
```

---

**Pierre MGI** — 2016-11-10

This command returns always true if the falling object is attached to some other object with the [attachTo](../commands/attachTo.md) command, like for vehicle air drop with parachute.

---

**Gippo** — 2017-04-26

Be aware: it is not reliable on remote objects.

<sub>Source: [BI Community Wiki — isTouchingGround](https://community.bistudio.com/wiki/isTouchingGround) (revision 376406).</sub>