---
name: "moveOut"
type: command
status: ok
groups: ["Unit Control"]
arma3_since: "0.50"
locality: {"argument": "global", "effect": "global", "server_exec": false}
source: https://community.bistudio.com/wiki/moveOut
revid: 349641
updated: 2023-11-16T22:02:40Z
---

# moveOut

*Command · Unit Control · Arma 3 v0.50 · introduced in Arma 2 v1.00*

Locality: arguments **global** · effect **global**

## Description

Moves the soldier out of the vehicle.

Notes:
- Works for both AI and player entities
- AI unit gets back in - unless is under player command or combined with other sqf commands ([orderGetIn](../commands/orderGetIn.md) false, [allowGetIn](../commands/allowGetIn.md) false or [leaveVehicle](../commands/leaveVehicle.md))
- Respects the vehicle's lock state (same as [action "Eject"](../topics/Actions.md#eject)) - unlike [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md). It will work for [player](../commands/player.md) entities regardless though
- Still executes when the vehicle is moving/flying (same as [action "Eject"](../topics/Actions.md#eject)) - unlike [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md)
- Without vehicle's position's get out animation - unlike [action eject](../topics/Actions.md#eject), [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md)
- Immediately - unlike [action eject](../topics/Actions.md#eject), [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md)
- Works also on dead units (same as [action "Eject"](../topics/Actions.md#eject) (but one after another)) - unlike [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md)
- Does not work for UAV crew
- Does not work for [remoteControl](../commands/remoteControl.md)led units
- Works on [unconscious](../commands/setUnconscious.md) (same as [action "Eject"](../topics/Actions.md#eject) (but one after another)) - unlike [doGetOut](../commands/doGetOut.md), [commandGetOut](../commands/commandGetOut.md) (unless AI under player command)

## Syntax

### Syntax 1

```sqf
moveOut soldier
```

**Parameters:**

- `soldier`: [Object](../topics/Object.md) - unit (only a living unit before Arma 3 v2.06)

**Returns:** [Nothing](../topics/Nothing.md)

### Syntax 2

*since arma3 2.06*

```sqf
soldier moveOut vehicle
```

**Parameters:**

- `soldier`: [Object](../topics/Object.md) - unit
- `vehicle`: [Object](../topics/Object.md) - vehicle could be [objNull](../commands/objNull.md), in this case the command is identical to the main syntax.

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
{ if (lifeState _x == "UNCONSCIOUS") then { moveOut _x } } forEach crew cursorTarget;
```

### Example 2

Move out player just before he dies:

```sqf
player addEventHandler [
    "HandleDamage", 
    format [
        'if (switch (_this select 1) do {
            case "": { _this select 2 >= 1 };
            case "head": {_this select 2 >= %1};
            case "body": {_this select 2 >= %2};
            default {false};
        }) then {moveOut player}',
        getNumber (configFile >> "CfgFirstAid" >> "CriticalHeadHit"),
        getNumber (configFile >> "CfgFirstAid" >> "CriticalBodyHit")
    ]
];
```

## See also

[Arma 3: Actions](../topics/Actions.md) · [doGetOut](../commands/doGetOut.md) · [commandGetOut](../commands/commandGetOut.md) · [leaveVehicle](../commands/leaveVehicle.md) · [moveInDriver](../commands/moveInDriver.md) · [moveInGunner](../commands/moveInGunner.md) · [moveInCommander](../commands/moveInCommander.md) · [moveInTurret](../commands/moveInTurret.md) · [moveInCargo](../commands/moveInCargo.md) · [isTurnedOut](../commands/isTurnedOut.md)

## Community notes

**.kju** — 2020-08-07

This seems no longer true in Arma 3:

*Does not work on dead [crew](../commands/crew.md) - Use [setPos](../commands/setPos.md) family of commands to move dead units out soon after they became dead. After awhile dead unit's group becomes [grpNull](../commands/grpNull.md) and it cannot be moved out at all.*

<sub>Source: [BI Community Wiki — moveOut](https://community.bistudio.com/wiki/moveOut) (revision 349641).</sub>