---
name: "playSound"
type: command
status: ok
groups: ["Sounds"]
arma3_since: "0.50"
locality: {"argument": null, "effect": "local", "server_exec": false}
source: https://community.bistudio.com/wiki/playSound
revid: 349659
updated: 2023-11-18T17:02:31Z
---

# playSound

*Command · Sounds · Arma 3 v0.50 · introduced in Operation Flashpoint v1.00*

Locality: effect **local**

## Description

Plays a sound from CfgSounds. Sound can be defined in [missionConfigFile](../commands/missionConfigFile.md), [configFile](../commands/configFile.md) or [campaignConfigFile](../commands/campaignConfigFile.md).

## Syntax

### Syntax 1

```sqf
playSound soundName
```

**Parameters:**

- `soundName`: [String](../topics/String.md)

**Returns:** [Object](../topics/Object.md) - the speaker object ([Nothing](../topics/Nothing.md) before Arma 3 v2.00)

### Syntax 2

```sqf
playSound [soundName, isSpeech, offset]
```

**Parameters:**

- `soundName`: [String](../topics/String.md)
- `isSpeech`: [Boolean](../topics/Boolean.md) or Arma 3 v2.04 [Number](../topics/Number.md) - (Optional, default [false](../commands/false.md))
  - 0/[false](../commands/false.md) = play as sound ([fadeSound](../commands/fadeSound.md) applies)
  - 1/[true](../commands/true.md) = play as speech ([fadeSpeech](../commands/fadeSpeech.md) applies), filters are not applied to it (i.e. house or vehicle interior one)
  - 2 = play as sound ([fadeSound](../commands/fadeSound.md) applies) without interior/vehicle muffling
- `offset`: [Number](../topics/Number.md) - (Optional, default 0) offset in seconds. Same as [playMusic](../commands/playMusic.md) *(since arma3 2.00)*

**Returns:** [Object](../topics/Object.md) - the speaker object ([Nothing](../topics/Nothing.md) before Arma 3 v2.00)

## Examples

### Example 1

```sqf
playSound "soundname";
```

### Example 2

Start a sound and then stop it after 1.2 second:

```sqf
playSound "AlarmCar";
0 spawn
{
    _sound = ASLToAGL [0,0,0] nearestObject "#soundonvehicle";
    sleep 1.2;
    deleteVehicle _sound;
};

// since Arma 3 v2.00
_source = playSound "AlarmCar";
_source spawn
{
    sleep 1.2;
    deleteVehicle _this;
};
```

### Example 3

Start a sound and wait until it is finished:

```sqf
playSound "Alarm";
hint "Started!";
0 spawn
{
    _sound = ASLToAGL [0,0,0] nearestObject "#soundonvehicle";
    waitUntil {isNull _sound};
    hint "Finished!";
};

// since Arma 3 v2.00
private _source = playSound "Alarm";
_source spawn
{
    waitUntil { isNull _this };
    hint "Finished!";
};
```

## See also

[playSound3D](../commands/playSound3D.md) · [sideRadio](../commands/sideRadio.md) · [say](../commands/say.md) · [playMusic](../commands/playMusic.md) · [say2D](../commands/say2D.md) · [say3D](../commands/say3D.md) · [createSoundSource](../commands/createSoundSource.md) · [playSoundUI](../commands/playSoundUI.md)

## Community notes

**Hardrock** — 2006-08-04

*Notes from before the conversion:*

For dialogue involving living units it is better to use [say](../commands/say.md),
[playSound](../commands/playSound.md) will play a sound at the location of the player,
[say](../commands/say.md) will play a sound at the location of the unit that is speaking, and it will only play that sound if the unit is alive.

---

**PiZZADOX** — 2014-12-28

As you may have noticed, the parameter for playsound/say3d that deals with the "volume" of the sound played has little to do with the effective loudness heard in game. What it is alters is the drop off for fading the sound at a distance. A higher decibel or integer value will increase the distance before any sort of fading will take place. The actual volume of the sound file played will factor in to this, as it does throughout the playing action.
==== Amplifying the Sound ====
Modifying the effective volume of sounds played by the engine is possible by "spamming" the sounds. By quickly playing the sounds overtop of one another, you can effectively amplify the volume

This example

```sqf
playSound "soundname";
playSound "soundname";
```

Will effectively amplify the sound by a sensed 2x. The volume of the sound file itself will still affect the sound volume as it appears as though the arma engine has no normalization for sound files added to it.

> [!NOTE]
> This technique may cause issues in sound quality in large multiplayer servers. I observed multiple instances when a triggered sound amplified with this method was out of sync with each other. Timing of the individual commands sent over the network is probably the issue. Recommend you compile your amplification code into a single finished function for better syncing for clients not activating the action/far away from the activation position.

<sub>Source: [BI Community Wiki — playSound](https://community.bistudio.com/wiki/playSound) (revision 349659).</sub>