---
name: "radioChannelCreate"
type: command
status: ok
groups: ["Radio and Chat", "Custom Radio and Chat"]
arma3_since: "0.50"
locality: {"argument": "global", "effect": "global", "server_exec": true}
source: https://community.bistudio.com/wiki/radioChannelCreate
revid: 378309
updated: 2026-04-01T22:48:12Z
---

# radioChannelCreate

*Command · Radio and Chat, Custom Radio and Chat · Arma 3 v0.50 · introduced in Take On Helicopters v1.00*

Locality: arguments **global** · effect **global** · **server execution only**

## Description

Create a custom radio channel with the given color, label, call sign and registered characters.
The **custom channel ID** returned can be used to manipulate the created channel later.
There are **50** slots (10 slots before Arma 3 v2.22) for custom radio channels which would correspond to channels 6..15 and 26..65 (see [getPlayerChannel](../commands/getPlayerChannel.md)).
The command will find an unused index in this range and create it when found.

## Syntax

```sqf
radioChannelCreate [color, label, callSign, units, sentenceType]
```

**Parameters:**

- `color`: [Array](../topics/Array.md) - [RGBA color](../topics/Color.md) values
- `label`: [String](../topics/String.md) - label
- `callSign`: [String](../topics/String.md) or Arma 3 v2.22 [Array](../topics/Array.md) of [String](../topics/String.md)s - see [radioChannelSetCallSign](../commands/radioChannelSetCallSign.md)
- `units`: [Array](../topics/Array.md) of [Object](../topics/Object.md)s - units in the channel
- `sentenceType`: [Boolean](../topics/Boolean.md) - (Optional, default [true](../commands/true.md))
  - [true](../commands/true.md) - use *Protocol* message color from `getArray (configFile >> "RscChatListDefault" >> "colorMessageProtocol")`
  - [false](../commands/false.md) - use *Normal* message color from `getArray (configFile >> "RscChatListDefault" >> "colorMessage")`

**Returns:** [Number](../topics/Number.md) - created **custom channel ID** (used in [customChat](../commands/customChat.md) command), 0 if failed. (see [BIS_fnc_channelNumToRadioChannelID](../functions/BIS_fnc_channelNumToRadioChannelID.md), [BIS_fnc_radioChannelIDToChannelNum](../functions/BIS_fnc_radioChannelIDToChannelNum.md))

## Examples

### Example 1

```sqf
_channelID = radioChannelCreate [[0.96, 0.34, 0.13, 0.8], "Q-dance Radio", "%UNIT_NAME", [player1, player2]];
```

### Example 2

```sqf
_channelID = radioChannelCreate [[0.96, 0.34, 0.13, 0.8], "Q-dance Radio", "%UNIT_NAME", [player1, player2], true];
// using true also disables automatic quotes for chat in channel (Arma 3)
```

### Example 3

Create custom channel and add all players to it, present and JIP:

```sqf
if (isServer) then
{
    private _channelName = "Q-dance Radio";
    private _channelID = radioChannelCreate [[0.96, 0.34, 0.13, 0.8], _channelName, "%UNIT_NAME", []];
    if (_channelID == 0) exitWith {diag_log format ["Custom channel '%1' creation failed!", _channelName]};
    [_channelID, {_this radioChannelAdd [player]}] remoteExec ["call", [0, -2] select isDedicated, _channelName];
};
```

## See also

[radioChannelAdd](../commands/radioChannelAdd.md) · [radioChannelRemove](../commands/radioChannelRemove.md) · [radioChannelSetCallSign](../commands/radioChannelSetCallSign.md) · [radioChannelSetLabel](../commands/radioChannelSetLabel.md) · [customChat](../commands/customChat.md) · [customRadio](../commands/customRadio.md) · [setCurrentChannel](../commands/setCurrentChannel.md) · [currentChannel](../commands/currentChannel.md) · [enableChannel](../commands/enableChannel.md) · [channelEnabled](../commands/channelEnabled.md) · [getPlayerChannel](../commands/getPlayerChannel.md) · [radioChannelInfo](../commands/radioChannelInfo.md)

## Community notes

**Killzone_Kid** — 2016-01-21

Make sure you add all units you intend to speak or receive messages on created custom channel to the channel.

---

**Hypoxic125** — 2022-11-01

Units are removed from the chat channel on RESPAWN. Be sure to add units back to their custom chat channels upon respawn via [onPlayerRespawn.sqf](../topics/Event_Scripts.md#onplayerrespawn-sqf) or [Respawn Event Handler](../topics/Event_Handlers.md#respawn).

<sub>Source: [BI Community Wiki — radioChannelCreate](https://community.bistudio.com/wiki/radioChannelCreate) (revision 378309).</sub>