---
name: "remoteExecutedJIPID"
type: command
status: ok
groups: ["Multiplayer"]
arma3_since: "2.18"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/remoteExecutedJIPID
revid: 369745
updated: 2024-10-08T15:06:58Z
---

# remoteExecutedJIPID

*Command · Multiplayer · Arma 3 v2.18*

## Description

Returns JIP ID of the persistent call generated from JIP queue for the joining player (see [remoteExec](../commands/remoteExec.md)).

## Syntax

```sqf
remoteExecutedJIPID
```

**Returns:** [String](../topics/String.md) - JIP ID

## Examples

### Example 1

```sqf
_jipid = remoteExecutedJIPID;
```

### Example 2

```sqf
/* 
Have mission with 2 players.
First player starts local server and executes given code
Second player joins the server and sees the 'all good' message
Second player logs out 
First player kills 'bob'
Second player joins back and sees 'removing JIP call' message
Second player logs out then joins back in, no message as call was removed
*/

private _fnc = 
{
    if (isRemoteExecutedJIP) then
    {
        remoteExecutedJIPID splitString "|" params ["_myID", "_netID"];
        private _obj = objectFromNetId _netID;
        if (!alive _obj) then
        {
            hint "object is dead or deleted, removing JIP call";
            remoteExec ["", remoteExecutedJIPID];
        }
        else
        {
            hint "JIP call, all good, doing something";
        };
    };
};

private _bob = group player createUnit [typeOf player, position player, [], 0, "NONE"];
private _myID = "lalala";
private _jipID = [_myID, netId _bob] joinString "|";
[[], _fnc] remoteExec ["call", 0, _jipId];
```

## See also

[remoteExecutedOwner](../commands/remoteExecutedOwner.md) · [isRemoteExecuted](../commands/isRemoteExecuted.md) · [isRemoteExecutedJIP](../commands/isRemoteExecutedJIP.md) · [remoteExec](../commands/remoteExec.md) · [remoteExecCall](../commands/remoteExecCall.md) · [canSuspend](../commands/canSuspend.md) · [publicVariableClient](../commands/publicVariableClient.md) · [admin](../commands/admin.md) · [owner](../commands/owner.md) · [clientOwner](../commands/clientOwner.md) · [groupOwner](../commands/groupOwner.md) · [didJIPOwner](../commands/didJIPOwner.md)

<sub>Source: [BI Community Wiki — remoteExecutedJIPID](https://community.bistudio.com/wiki/remoteExecutedJIPID) (revision 369745).</sub>