---
name: "setMissileTargetPos"
type: command
status: ok
groups: ["Object Manipulation", "Weapons"]
arma3_since: "1.92"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/setMissileTargetPos
revid: 377534
updated: 2026-01-02T06:53:19Z
---

# setMissileTargetPos

*Command · Object Manipulation, Weapons · Arma 3 v1.92*

## Description

Sets a guided munition target position.
The munition must have `manualControl` config entry to use this command.
The target position has to be inside the missile's configured targeting cone for the command to work.

## Syntax

```sqf
munition setMissileTargetPos position
```

**Parameters:**

- `munition`: [Object](../topics/Object.md)
- `position`: [PositionATL](../topics/Position.md#positionatl)

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
missile1 setMissileTargetPos unitAimPosition tank1;
```

### Example 2

```sqf
private _missile = createVehicle ["M_Scalpel_AT", player modelToWorld [0,0,100], [], 0, "CAN_COLLIDE"];
_missile setMissileTargetPos (player modelToWorld [0,100,0]);
```

## See also

[missileTargetPos](../commands/missileTargetPos.md) · [setMissileTarget](../commands/setMissileTarget.md) · [missileTarget](../commands/missileTarget.md) · [missileState](../commands/missileState.md)

## Community notes

**Benargee** — 2020-04-13

To get list of compatible missiles with `manualControl = 1`, use the below script and paste the clipboard results to a text editor.

```sqf
private _cfgCount = count (configfile >> "CfgAmmo");
private _pasteStr = "";

for "_x" from 0 to (_cfgCount - 1) do {
    _cfg = (configFile >> "CfgAmmo") select _x;
    _ammoClassName = configName _cfg;
    private _manCtrl = getNumber (configFile >> "CfgAmmo" >> _ammoClassName >> "manualControl");
    if (_manCtrl > 0) then {
            _pasteStr = _pasteStr + _ammoClassName + endl;
    };
};

copyToClipboard _pasteStr;
```

---

**Lou Montana** — 2022-08-12

Tested with a player-controlled AH-99 firing DAGR, a civilian helicopter named `heli` above water/land, and the following code:

```sqf
if (!isNil "EH") then
{
    vehicle player removeEventHandler ["Fired", EH];
};
EH = vehicle player addEventHandler ["Fired", {
params ["_unit", "_weapon", "_muzzle", "_mode", "_ammo", "_magazine", "_missile", "_gunner"];
    _missile setMissileTargetPos getPosATL heli; // changing here getPosATL / getPosASL / getPos
    systemChat str [_missile, missileTarget _missile, missileTargetPos _missile];
}];
```

<sub>Source: [BI Community Wiki — setMissileTargetPos](https://community.bistudio.com/wiki/setMissileTargetPos) (revision 377534).</sub>