---
name: "skipTime"
type: command
status: ok
groups: ["Time", "Environment"]
arma3_since: "0.50"
locality: {"argument": null, "effect": null, "server_exec": true}
source: https://community.bistudio.com/wiki/skipTime
revid: 369075
updated: 2024-09-02T20:25:00Z
---

# skipTime

*Command · Time, Environment · Arma 3 v0.50 · introduced in Operation Flashpoint v1.00*

Locality: **server execution only**

## Description

Jumps the specified number of hours forward or backward.
The time of day and tides are adjusted, but no changes are made to any units. If present, the lower level of clouds instantly jump to the position they would be in if time had passed normally.

## Syntax

```sqf
skipTime duration
```

**Parameters:**

- `duration`: [Number](../topics/Number.md) - hours to skip. A positive value will create a forward time jump, a negative value will jump backwards.

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
skipTime 5;
```

### Example 2

```sqf
skipTime (5/60); // be sure to use parentheses, otherwise here (skipTime 5)/60 will happen
```

### Example 3

```sqf
while {true} do 
{
    skipTime 0.00333;
    sleep 0.1; // smooth time transition
};
```

### Example 4

```sqf
skipTime ((_timeToSkipTo - dayTime + 24) % 24); // skip forward to a specific time, irrespective of the current mission time
```

## Multiplayer

In Arma 3 (around v1.14) [skipTime](../commands/skipTime.md) executed on the server will get synced in 5 seconds or so with all the clients. It will also be [JIP](../topics/Multiplayer_Scripting.md#join-in-progress) compatible. [skipTime](../commands/skipTime.md) executed on a client will change time on client for about 5 seconds after which it will sync back to server time.

For other games' behaviour, see [Multiplayer Scripting#Join In Progress](../topics/Multiplayer_Scripting.md#join-in-progress).

> [!IMPORTANT]
> Since Arma 3 v2.10 [skipTime](../commands/skipTime.md) is limited to max +/- 1000 hours per skip for game stability. The command is intended for short time jumps. For large intervals, use [setDate](../commands/setDate.md).

## See also

[setDate](../commands/setDate.md) · [accTime](../commands/accTime.md) · [setTimeMultiplier](../commands/setTimeMultiplier.md) · [timeMultiplier](../commands/timeMultiplier.md) · [BIS_fnc_setDate](../functions/BIS_fnc_setDate.md)

## Community notes

**Ceeeb** — 2007-04-17

In ArmA & OFP, skipTime does not actually estimate weather changes beyond moving the clouds across the sky.
Weather counters continue as if no time has passed.
The [setDate](../commands/setDate.md) command can be used instead of skiptime to change the time *without* the visual give-away of the lower clouds jumping.

---

**.kju** — 2011-11-02

I cannot confirm this for OA 1.60 beta (85889):
MP: Even though the immediate effect of skipTime is only local,
the new time will propagate through the network after 30 seconds or so.
Instead the [date](../commands/date.md), which includes time, is synced automatically for new JIP clients - NOT for present instances.
So one has to apply skipTime on all instances in MP (server + all present clients).

---

**Killzone_Kid** — 2013-08-25

This command is blocking and in some cases it may take up to 1.5 seconds (probably depends on CPU) for it to calculate the changes to the environment, during which the game will microfreeze. It largely depends on weather changes, which are quite random. However one thing remains consistent, [skipTime](../commands/skipTime.md) 24 hours is always almost instant. This is quite helpful when used in conjunction with commands such as [setOvercast](../commands/setOvercast.md) for instant and seamless effect. To try it yourself use this script:

```sqf
0 spawn {
    for "_i" from 1 to 24 do {
        _time = diag_tickTime;
        skipTime _i;
        diag_log  [_i, diag_tickTime - _time];
        sleep 3;
    };
};
```

One of the results (results will vary depending on weather conditions):

```
[1,1.44507]
[2,1.46118]
[3,1.33105]
[4,1.396]
[5,0.0310059]
[6,1.37891]
[7,1.4502]
[8,1.37817]
[9,1.37695]
[10,1.37012]
[11,1.448]
[12,1.32593]
[13,1.45508]
[14,1.448]
[15,0.0349121]
[16,0.0368652]
[17,1.25903]
[18,1.38599]
[19,1.4519]
[20,0.052002]
[21,0.0400391]
[22,0.0490723]
[23,1.35205]
[24,0.0151367] // this is always the lowest
```

<sub>Source: [BI Community Wiki — skipTime](https://community.bistudio.com/wiki/skipTime) (revision 369075).</sub>