---
name: "BIS_fnc_MP"
type: function
status: deprecated
replaced_by: ["remoteExec", "remoteExecCall"]
groups: ["Multiplayer"]
arma3_since: "0.50"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/BIS_fnc_MP
revid: 330764
updated: 2022-11-01T15:45:23Z
---

# BIS_fnc_MP

*Function · Multiplayer · Arma 3 v0.50*

> [!WARNING]
> This function is deprecated. Use [remoteExec](../commands/remoteExec.md) or [remoteExecCall](../commands/remoteExecCall.md) instead.

## Description

Send function for remote execution (and executes locally if conditions are met).

> [!WARNING]
> Arma 3 v1.50 This function has been replaced by [remoteExec](../commands/remoteExec.md) and [remoteExecCall](../commands/remoteExecCall.md). While [BIS_fnc_MP](../functions/BIS_fnc_MP.md) still works (to provide backwards compatibility), it is now deprecated and should no longer be used. See [Arma 3: Remote Execution](../topics/Remote_Execution.md) for more information.

## Syntax

```sqf
[params, functionName, target, isPersistent, isCall] call BIS_fnc_MP
```

**Parameters:**

- **params**: [Anything](../topics/Anything.md) - function arguments. Variables can be local.
- **functionName**: [String](../topics/String.md) - function or scripting command name.
- **target**:
  - [Object](../topics/Object.md) - the function will be executed only where unit is local [default: everyone]
  - [String](../topics/String.md) - the function will be executed only where object or group defined by the variable with passed name is local
  - [Boolean](../topics/Boolean.md) - [true](../commands/true.md) to execute on each machine (including the one where the function was called from), false to execute it on server only
  - [Number](../topics/Number.md) - function will be executed only on client with the given [owner](../commands/owner.md) ID
  - [Side](../topics/Side.md) - function will be executed only on clients where the player is on the specified side
  - [Group](../topics/Group.md) - function will be executed only on clients where the player is in the specified group
  - [Array](../topics/Array.md) - array of targets of types listed above
- **isPersistent**: [Boolean](../topics/Boolean.md) - (Optional, default [false](../commands/false.md)) true for persistent call (will be called now and for every JIP client)
- **isCall**: [Boolean](../topics/Boolean.md) - (Optional, default [false](../commands/false.md)) true if function should be [called](../commands/call.md) on target machine, false to [spawn](../commands/spawn.md) it

**Returns:** [Array](../topics/Array.md) - sent packet

## Examples

### Example 1

```sqf
// logs a message for every player on the server.
["Imma spamming your log!", "BIS_fnc_log"] call BIS_fnc_MP;
```

### Example 2

```sqf
// send a hint containing "Hello World" to every player, including the ones who joins later using JIP.
["Hello World", "hint", true, true] call BIS_fnc_MP;
```

### Example 3

```sqf
// executes "playerConnected.sqf" script on server every time a player joins the game.
[[[], "playerConnected.sqf"], "BIS_fnc_execVM", false, true] call BIS_fnc_MP;
```

### Example 4

```sqf
// adds action to every player including JIP. "..." = further optional arguments (see addAction)
[[player], ["My Action Title", "myAction.sqf" /* etc */]], "addAction", true, true] call BIS_fnc_MP;
```

## See also

[BIS_fnc_MPexec](../functions/BIS_fnc_MPexec.md) · [Arma 3 Remote Execution](../topics/Remote_Execution.md)

## Community notes

**Fireball** — 2013-04-02

Note that the function you provide as argument is *not* transferred to the remote client or server.

You will have to use either
1. functions defined in global namespace
1. functions defined depending on where you want to execute them; in server or/and client code if you separate it using conditions on [isServer](../commands/isServer.md) or [local](../commands/local.md) [player](../commands/player.md)
1. pre-defined BIS functions

You can also execute scripts remotely like this:

```sqf
["myScript.sqf", "BIS_fnc_execVM", true, true] call BIS_fnc_MP;
```

Or transfer code as parameter (not recommended) like that:

```sqf
[{ hint "Hello World!"; }, "BIS_fnc_spawn", true, true] call BIS_fnc_MP;
```

---

**kylania** — 2013-07-04

> One key note when designing a mission/script is to limit the amount of use you make of the isPersistent parameter. It is not recommended to use it often for vehicle creation, object creation, etc.
> Each time you use the isPersistent parameter it adds to a BIS Logic which is used to sync all clients and new clients that join, excessive use of the command will make the logic build up and eventually you will cause the server to desync out because of the massive amount of data it has to send to all clients and JIP clients to try to keep them in sync.
>
> It is highly recommended to make as little use as possible of the isPersistent option unless you have to for network performance sake.

---

**Killzone_Kid** — 2013-12-10

If you need to achieve a single global execution of an existing function on all PCs including your own, the syntax could not be any more simple than: [arguments, functionname] [call](../commands/call.md) [BIS_fnc_MP](../functions/BIS_fnc_MP.md); This is particularly useful with commands such as [switchMove](../commands/switchMove.md) where the command effect is [local](../topics/Multiplayer_Scripting.md#locality).

For example to make sure animation is played on every PC, first define a global function on every PC (maybe inside init.sqf):

```sqf
switchMoveEverywhere = compileFinal "
    _this select 0 switchMove (_this select 1);
";
```

Then execute [BIS_fnc_MP](../functions/BIS_fnc_MP.md) on only one PC which will in return execute *switchMoveEverywhere* function everywhere:

```sqf
[
    [
        player,
        "AmovPercMstpSrasWrflDnon_AadjPpneMstpSrasWrflDleft"
    ],
    "switchMoveEverywhere"
] call BIS_fnc_MP;
```

---

**Waffle SS.** — 2015-05-23

Adding onto what Killzone_Kid said, a custom function isn't necessary when using only a single command.

```sqf
[
    [player, "AmovPercMstpSrasWrflDnon_AadjPpneMstpSrasWrflDleft"],
    "switchMove"
] call BIS_fnc_MP;
```

---

**Warka** — 2015-06-08

From version 1.50 the function [BIS_fnc_MP](../functions/BIS_fnc_MP.md) will use the engine based remote execution.
- This will positively affect its performance, namely processing speed and amount of transferred data.
- The syntax and functionality of [BIS_fnc_MP](../functions/BIS_fnc_MP.md) will remain same to retain the backward compatibility.
- To prevent abusing of the [remoteExec](../commands/remoteExec.md) and [remoteExecCall](../commands/remoteExecCall.md) commands the [BIS_fnc_MP](../functions/BIS_fnc_MP.md) will use, the content authors will be able to define the operation modes as well as white-lists for commands/functions for clients and server separately.
- White-lists defined in *CfgRemoteExecCommands* and *CfgRemoteExecFunctions* won't be supported from 1.48 as they will be replaced by the new structure more powerful and detailed structure: CfgRemoteExec.

---

**Waffle SS.** — 2015-07-20

Pay close attention to where and when you call [BIS_fnc_MP](../functions/BIS_fnc_MP.md). If you use it on the server during init, it will probably run before the player is loaded into the server, and the player behaves more like a JIP. Either waiting for the briefing to end ([time](../commands/time.md) > 0), or using the JIP parameter in [BIS_fnc_MP](../functions/BIS_fnc_MP.md) are two ways of getting around this issue.

<sub>Source: [BI Community Wiki — BIS fnc MP](https://community.bistudio.com/wiki/BIS_fnc_MP) (revision 330764).</sub>