---
name: "BIS_fnc_createTooltip"
type: function
status: ok
groups: ["GUI"]
arma3_since: "1.78"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/BIS_fnc_createTooltip
revid: 352466
updated: 2024-02-11T23:22:48Z
---

# BIS_fnc_createTooltip

*Function · GUI · Arma 3 v1.78*

## Description

Shows group tooltip. Adapted for Tac Ops DLC for use in the animated briefings.

## Syntax

```sqf
[input, display, mousePos] call BIS_fnc_createTooltip
```

**Parameters:**

- `input`: [Array](../topics/Array.md) format [config, parameters]:
  - config: [Config](../topics/Config.md) - group from CfgORBAT
  - parameters: [Array](../topics/Array.md) - group params returned by [BIS_fnc_ORBATGetGroupParams](../functions/BIS_fnc_ORBATGetGroupParams.md)
- `display`: [Display](../topics/Display.md) - display where tooltip controls group is created
- `mousePos`: [Array](../topics/Array.md) - mouse position in format [x, y]

**Returns:** [Boolean](../topics/Boolean.md)

## Examples

### Example 1

```sqf
// enable icons in 2D and 3D
setGroupIconsVisible [true, true];
setGroupIconsSelectable true;

// add the icon for all existing groups
private _group = group player;
private _color = [side _group, false] call BIS_fnc_sideColor;
_group addGroupIcon ["o_inf", [0, 0]];
_group setGroupIconParams [_color, groupID _group, 1, true];

// show tooltip when hovering over group icon of player group
addMissionEventHandler ["GroupIconOverEnter",
{
    [configFile >> "CfgORBAT" >> "BIS" >> "I_AAF", findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
}];

// remove tooltip when leaving group icon area
addMissionEventHandler ["GroupIconOverLeave",
{
    [nil, findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
}];
```

### Example 2

```sqf
private _marker = createMarker ["marker_0", [worldSize / 2, worldSize / 2]];
_marker setMarkerType "flag_Germany";
_marker setMarkerText "GERMANY";

_marker = createMarker ["marker_1", [worldSize / 1.5, worldSize / 1.5]];
_marker setMarkerType "flag_Altis";
_marker setMarkerText "ALTIS";

findDisplay 12 displayCtrl 51 ctrlAddEventHandler
[
    "draw",
    {
        params ["_ctrlMap"];

        ctrlMapMouseOver _ctrlMap params [["_type", ""], ["_markerName", ""]];

        if (_type == "marker") then
        {
            private _markerTexture = getText (configFile >> "CfgMarkers" >> markerType _markerName >> "icon");
            private _markerText = markerText _markerName;

            [[nil, nil, _markerName, nil, _markerTexture, nil, nil, nil, _markerText, nil, nil, "Some Description"], findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
        }
        else
        {
            [nil, findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
        };
    }
];
```

## See also

[BIS_fnc_ORBATGetGroupParams](../functions/BIS_fnc_ORBATGetGroupParams.md)

<sub>Source: [BI Community Wiki — BIS fnc createTooltip](https://community.bistudio.com/wiki/BIS_fnc_createTooltip) (revision 352466).</sub>