---
name: "BIS_fnc_moduleLightning"
type: function
status: ok
groups: ["Modules"]
arma3_since: "1.16"
locality: {"argument": null, "effect": null, "server_exec": false}
source: https://community.bistudio.com/wiki/BIS_fnc_moduleLightning
revid: 373909
updated: 2025-06-27T14:16:20Z
---

# BIS_fnc_moduleLightning

*Function · Modules · Arma 3 v1.16*

Locality: executed with **spawn**

## Description

Zeus lightning strike.

> [!IMPORTANT]
> Note that the *target* object will be deleted by the function (part of how Zeus modules work) if it can be edited by any curators (which is checked by the [objectCurators](../commands/objectCurators.md) command).

## Syntax

```sqf
[target, nil, activate] call BIS_fnc_moduleLightning
```

**Parameters:**

- `target`: [Object](../topics/Object.md) - where the lightning bolt hits - **will** be deleted by the function!
- `nil`: [Nothing](../topics/Nothing.md) - not used
- `activate`: [Boolean](../topics/Boolean.md) - [true](../commands/true.md) to activate, [false](../commands/false.md) does nothing

**Returns:** [Nothing](../topics/Nothing.md)

## Examples

### Example 1

```sqf
player addAction 
[
    "Eat that!", 
    {
        private _tempTarget = createSimpleObject ["Land_HelipadEmpty_F", getPosASL cursorTarget];
        [_tempTarget, nil, true] spawn BIS_fnc_moduleLightning;
        cursorTarget setDamage 1;
    },
    [],
    1.5, 
    true, 
    true, 
    "",
    "!isNull cursorTarget"
];
```

### Example 2

```sqf
[] spawn // Who gets hit first? ;-)
{
    {
        private _tempTarget = createSimpleObject ["Land_HelipadEmpty_F", getPosASL _x];
        [_tempTarget, nil, true] spawn BIS_fnc_moduleLightning;
        sleep (1 + random 4);
    } forEach (allPlayers call BIS_fnc_arrayShuffle);
};
```

## See also

Arma 3 Zeus

## Community notes

**Smith.UA** — 2025-06-26

Please note that the function makes the visual effects (lightning model and light) visible only to the client on which the function was executed.

The explosion sound, crater and damage will only be generated (globally) on the client where the target is local or the target curator is local to the client.

If you want to call lightning globally, you must call this function on all clients:

```sqf
// consider remoteExec limitations by CfgRemoteExec
[target, nil, true] remoteExec ["BIS_fnc_moduleLightning"];
```

<sub>Source: [BI Community Wiki — BIS fnc moduleLightning](https://community.bistudio.com/wiki/BIS_fnc_moduleLightning) (revision 373909).</sub>