---
name: "Code Optimisation"
type: topic
source: https://community.bistudio.com/wiki/Code_Optimisation
revid: 378687
updated: 2026-05-26T00:40:51Z
---
# Code Optimisation
> [!NOTE]
> This page is about [Code Optimisation](../topics/Code_Optimisation.md). For *conception* optimisation, see Mission Optimisation.
This article will try to be a general guide about improving your code **and** its performance.
- The first part ([Rules](../topics/Code_Optimisation.md#rules)) focuses on having a clean, readable and maintainable code.
- The second part ([Code optimisation](../topics/Code_Optimisation.md#code-optimisation)) is about **improving performance**, sometimes trading it against code readability.
- The third part ([Equivalent commands performance](../topics/Code_Optimisation.md#equivalent-commands-performance)) mentions commands that in appearance have identical effects but may differ in terms of performance according to the use you may have of them.
- The fourth part ([Conversion from earlier versions](../topics/Code_Optimisation.md#conversion-from-earlier-versions)) is a hopefully helpful, short guide about useful new commands or syntaxes to replace the old ways.
### Rules
In the domain of development, any rule is a rule of thumb. If a rule states for example that it is *better* that a line of code doesn't go over 80 characters, it doesn't mean that any line ***must not*** go over 80 characters; sometimes, the situation needs it. If you have a good structure, **do not** change your code to enforce a single arbitrary rule. If you break many of them, you may have to change something. Again, this is according to your judgement.
With that being said, here are the three basic rules to get yourself in the clear:
1. [Make it work](../topics/Code_Optimisation.md#make-it-work)
1. [Make it readable](../topics/Code_Optimisation.md#make-it-readable)
1. [Optimise then](../topics/Code_Optimisation.md#optimise-then)
#### Make It Work
> Premature optimization is the root of all evil.
Your first goal when coding is to make your code do what you want it does. A good way to reach this objective is to read and getting inspired by other people's code. If you understand it by reading it once, it is probably a good source of inspiration.
- When starting from scratch if you know what you want but miss the specific steps to get to your point, it is a good practice to write down in your native language what you want to do. E.g *Get [all the units](../commands/allUnits.md) [near](../commands/distance.md) [the city](../commands/locationPosition.md), and [for each](../commands/forEach.md) [west](../commands/side.md) soldier in them, [add 30% damage](../commands/setDamage.md)*.
- Use -showScriptErrors startup parameter and **make sure your code doesn't throw errors.** Not only will your code run slower but it may also *not work at all*. Be sure to read the error, isolate the issue and sort it out thanks to this Wiki.
- Read your Arma RPT (report) to read more details about the error that happened in your code.
#### Make It Readable
Whether you are cleaning your code or a different person's, you must understand the code without twisting your brain:
- While [SQF](../topics/SQF_Syntax.md) *is* (non-noticeably) impacted by variable name length, this should not take precedence on the fact that code must be readable by a human being. Variables like **_u** instead of **_uniform** should not be present.
- *One-lining* (putting everything in one statement) memory improvement is most of the time not worth the headache it gives when trying to read it. Don't overuse it.
- Indentation is important for the human mind, and space is too. Space is free, use it.
- Same goes for line return; it helps to see a code block wrapping multiple common instructions instead of having to guess where it starts and stops.
- Do you see the same code multiple times, only with different parameters? Now is the time to write a function!
- If you have a lot of [if](../commands/if.md)..[else](../commands/else.md), you may want to look at a [switch](../commands/switch.md) condition, or again break your code in smaller functions.
- Is your function code far too long? Break it in understandable-sized bites for your own sanity.
- Finally, camel-casing (namingLikeThis) your variables will naturally make the code more readable, especially for long names.
> [!NOTE]
> See **[Code Best Practices](../topics/Code_Best_Practices.md)** for more information.
See the following code:
_w=[]; {_w pushbackunique primaryweapon _x} foreach((allunits+alldeadmen) select{_x call BIS_fnc_objectside==east});
The same example is far more readable with proper spacing, good variable names and intermediate results:
_weaponNames = [];
_allUnitsAliveAndDead = allUnits + allDeadMen;
_allEastAliveAndDead = _allUnitsAliveAndDead select { _x call BIS_fnc_objectSide == east };
{ _weaponNames pushBackUnique primaryWeapon _x } forEach _allEastAliveAndDead;
##### Constants
Using a hard-coded constant more than once? Use preprocessor directives rather than storing it in memory or cluttering your code with numbers. Such as:
```sqf
a = _x + 1.053;
b = _y + 1.053;
```
And
```sqf
_buffer = 1.053;
a = _x + _buffer;
b = _y + _buffer;
```
Becomes
```sqf
#define BUFFER 1.053 // note: no semicolon
_a = _x + BUFFER;
_b = _y + BUFFER;
```
> [!NOTE]
> Using the `#define` macro only works within the current [SQF](../topics/SQF_Syntax.md) *file*. Such definition will not propagate anywhere else.
**Global** "constants" can be defined via a [Description.ext](../topics/Description.ext.md) declaration, though, and accessed using [getMissionConfigValue](../commands/getMissionConfigValue.md) command:
Declaration in [Description.ext](../topics/Description.ext.md):
```cpp
var1 = 123;
var2 = "123";
var3[] = { 1, 2, 3 };
rand = __EVAL(random 999);
```
Usage in code:
```sqf
hint str getMissionConfigValue "var1"; // 123 // 0.0007 ms
hint str getMissionConfigValue "var2"; // "123" // 0.0008 ms
hint str getMissionConfigValue "var3"; // [1,2,3] // 0.0017 ms
hint str getMissionConfigValue "rand"; // constant random, for example 935.038 // 0.0007 ms
```
The [getMissionConfigValue](../commands/getMissionConfigValue.md) command searching [Description.ext](../topics/Description.ext.md) from top to bottom,
it is better for a matter of performance to put all your definitions at the top of the file.
#### Optimise Then
Once you know what is what, you can understand your code better.
- Use [private variables](../topics/Variables.md#scopes) instead of global variables (preceded by an underscore) as much as possible.
- You were iterating multiple times on the same array?
- You should be able to spot your issue now.
- Are you using [execVM](../commands/execVM.md) on the same file, many times?
- Store your function in memory to avoid file reading every call ( e.g `_myFunction = compile preprocessFileLineNumbers "myFile.sqf";`).
- Is your variable name far too long?
- Find a smaller name, according to the variable scope;e.g:
```sqf
{ _opforUnitUniform = uniform _x; systemChat _opforUnitUniform; } forEach _allOpforUnits;
```
becomes
```sqf
{ _uniform = uniform _x; systemChat _uniform; } forEach _allOpforUnits;
```
### Code Optimisation
> [!IMPORTANT]
> **Please note:** Tests and benchmarks were done with the latest Arma 3 version at the time Arma 3 v1.82 with **Tank DLC**. Game engine performance may have changed since.
> Benchmark result in milliseconds (ms) is an average for **10000** iterations.
> [!NOTE]
> ● means you **must** change your ways today, *or with us you will ride…*
>
> ● means you may want to look at it if you are targeting pure performance
>
> ● means the gain is little to insignificant. Going through your code for this replacement is not worth it. You *may* only consider it for future code.
#### Scheduled and Unscheduled Environment
There are two code environment types, [scheduled](../topics/Scheduler.md#scheduled_environment) and [unscheduled](../topics/Scheduler.md#unscheduled_environment).
- A **scheduled** script has an execution time limit of **3 ms** before being suspended to the benefit of another script until its turn comes back. It is a bit slower than unscheduled, but [suspending](../commands/canSuspend.md) ([sleep](../commands/sleep.md), [waitUntil](../commands/waitUntil.md)) is allowed.
- An **unscheduled** script is not watched and will run without limitations. It is recommended for time-critical scripts, but [suspending](../commands/canSuspend.md) ([sleep](../commands/sleep.md), [waitUntil](../commands/waitUntil.md)) is **not** allowed!
> [!NOTE]
> See [Scheduler](../topics/Scheduler.md) for more information.
#### ● Variable Assignment
```sqf
private _myVar = [33, 66] select false; // 0.0013 ms
private _myVar = if (false) then { 33; } else { 66; }; // 0.0020 ms
private "_myVar"; if (false) then { _myVar = 33; } else { _myVar = 66; }; // 0.0025 ms
```
#### ● Lazy Evaluation
In [SQF](../topics/SQF_Syntax.md) the following code will evaluate every single condition, even if one fails:
```sqf
if (a && b && c) then {};
```
Even if `a` returns [false](../commands/false.md) (and thus the entire [Boolean](../topics/Boolean.md) expression can no longer become [true](../commands/true.md)), `b` and `c` will still be executed and evaluated regardless.
To avoid this behaviour, one can either imbricate [if](../commands/if.md) statements or use **lazy evaluation**. The latter is done like so:
```sqf
if (a && { b && { c } }) then {};
```
In the example above, condition evaluation stops once any condition evaluates to [false](../commands/false.md).
##### Influence on Semantics
Depending on the arrangement of the curly brackets, lazy evaluation can change the precedence (and therefore the semantics) of a condition. Consider this example:
| Expression | Condition Value | Evaluated Conditions | Result | | |
|---|---|---|---|---|---|
| `a` | `b` | `c` | | | |
| ```sqf
a && b \|\| c
``` | [false](../commands/false.md) | any [Boolean](../topics/Boolean.md) | [true](../commands/true.md) | `a`, `b`, `c` | [true](../commands/true.md) |
| ```sqf
a && {b} \|\| {c}
``` | `a`, `c` | [true](../commands/true.md) | | | |
| ```sqf
a && {b \|\| {c}}
``` | `a` | [false](../commands/false.md) | | | |
##### Performance
Using lazy evaluation is not always the best way as it can both speed up and slow down the code, depending on the current condition being evaluated:
```sqf
["true || { false || {false}}", nil, 100000] call BIS_fnc_codePerformance; // 0.00080 ms
["true || {false} || {false} ", nil, 100000] call BIS_fnc_codePerformance; // 0.00105 ms
["false || false || false ", nil, 100000] call BIS_fnc_codePerformance; // 0.00123 ms
["true || false || false ", nil, 100000] call BIS_fnc_codePerformance; // 0.00128 ms
["false || {false} || {false} ", nil, 100000] call BIS_fnc_codePerformance; // 0.00200 ms
```
#### ● Concatenating Strings
`myString = myString + otherString` works fine for small strings, however the bigger the string gets the slower the operation becomes:
```sqf
myString = ""; for "_i" from 1 to 10000 do { myString = myString + "123" }; // 290 ms
```
The solution is to use a string array that you will concatenate later:
```sqf
strings = [];
for "_i" from 1 to 10000 do { strings pushBack "123" };
strings = strings joinString ""; // 30 ms
```
#### ● Array Manipulation
##### Add Elements
New commands [append](../commands/append.md) and [pushBack](../commands/pushBack.md) hold the best score.
```sqf
_array = [0,1,2,3]; _array append [4,5,6]; // 0.0020 ms
_array = [0,1,2,3]; _array = _array + [4,5,6]; // 0.0023 ms
_array = [0,1,2,3]; { _array set [count _array, _x]; } forEach [4,5,6]; // 0.0080 ms
```
```sqf
_array = [0,1,2,3]; _array pushBack 4; // 0.0016 ms
_array = [0,1,2,3]; _array = _array + [4]; // 0.0021 ms
_array = [0,1,2,3]; _array set [count _array, _x]; // 0.0022 ms
```
##### Iterate Elements
**If [_x](../topics/Magic_Variables.md#x) is not required**, [for](../commands/for.md) is twice as fast as [forEach](../commands/forEach.md) - otherwise, use [forEach](../commands/forEach.md) (see results below).
```sqf
private _list = allUnits; // 64 units 256 units
// if the amount of loops is known
for "_i" from 0 to 63 do {}; // 0.0120 ms 0.0460 ms
for "_i" from 0 to count _list -1 do {}; // 0.0170 ms 0.0480 ms
for "_i" from 0 to count _list -1 do { private _x = _list select _i }; // 0.0500 ms 0.1896 ms <
for "_i" from 0 to count _list -1 do { private _x = _list select _i; _x setDamage 0 }; // 0.107 ms 0.39 ms
{} forEach _list; // 0.0250 ms 0.098 ms
{ _x setDamage 0 } forEach _list; // 0.0770 ms 0.312 ms
_list apply {}; // 0.0250 ms 0.098 ms
_list apply { _x setDamage 0 }; // 0.0770 ms 0.312 ms
private _i = 0;
while { _i < 64 } do { _i = _i + 1; }; // 0.048 ms 0.200 ms
// counts array every loop
private _i = 0;
while { _i < count _list } do { _i = _i + 1; }; // 0.062 ms 0.247 ms
private _i = 0;
while { _i < 64 } do { private _x = _list select _i; _i = _i + 1; }; // 0.086 ms 0.42 ms
```
##### Remove Elements
```sqf
_array = [0,1,2,3]; _array deleteAt 0; // 0.0015 ms
_array = [0,1,2,3]; _array set [0, objNull]; _array = _array - [objNull]; // 0.0038 ms
```
```sqf
_array = [0,1,2,3]; _array deleteRange [1, 2]; // 0.0018 ms
_array = [0,1,2,3]; { _array set [_x, objNull] } forEach [1,2]; _array = _array - [objNull]; // 0.0078 ms
```
#### ● Multiplayer Recommendations
- Do not saturate the network with information: [publicVariable](../commands/publicVariable.md) or public [setVariable](../commands/setVariable.md) shouldn't be used at high frequency, else **everyone's performance experience** is at risk!
- The server is supposed to have a good CPU and a lot of memory, use it: store functions, run them from it, send only the result to the clients
- [publicVariable](../commands/publicVariable.md) and [setVariable](../commands/setVariable.md) variable name length impacts network, be sure to send well-named, understandable variables
(*and not **playerNameBecauseThePlayerIsImportantAndWeNeedToKnowWhoTheyAreAllTheTimeEspeciallyInsideThisImpressiveFunction***)
- Use, use and use [remoteExec](../commands/remoteExec.md) & [remoteExecCall](../commands/remoteExecCall.md). Ditch [BIS_fnc_MP](../functions/BIS_fnc_MP.md) for good!
> [!NOTE]
> See [Multiplayer Scripting](../topics/Multiplayer_Scripting.md) for more information.
### Equivalent Commands Performance
#### ● call
[call](../commands/call.md) without arguments is faster than call with arguments:
```sqf
call {}; // 0.0007 ms
123 call {}; // 0.0013 ms
```
Since the variables defined in the parent scope will be available in the [call](../commands/call.md)ed child scope, it could be possible to speed up the code by avoiding passing arguments all together, for example writing:
```sqf
player addEventHandler ["HandleDamage", { call my_fnc_damage }];
```
instead of:
```sqf
player addEventHandler ["HandleDamage", { _this call my_fnc_damage }];
```
#### ● execVM and call
> [!IMPORTANT]
> Using [execVM](../commands/execVM.md) multiple times make the game read the file and recompile it every time.
>
> If you use the script more than once, store its code in a variable or better, make it a [Function](../topics/Functions_Library.md)!
```sqf
// myFile.sqf is an EMPTY file
private _myFunction = compile preprocessFileLineNumbers "myFile.sqf"; // compile time is done only once
call _myFunction; // 0.0009 ms
execVM "myFile.sqf"; // 0.275 ms
// myFile.sqf is BIS_fnc_showRespawnMenu
private _myFunction = compile preprocessFileLineNumbers "myFile.sqf"; // compile time is done only once
["close"] call _myFunction; // 0.0056 ms
["close"] execVM "myFile.sqf"; // 0.506 ms
```
#### ● loadFile, preprocessFile and preprocessFileLineNumbers
```sqf
// myFile.sqf is an empty file
loadFile "myFile.sqf"; // 0.219 ms
preprocessFile "myFile.sqf"; // 0.353 ms
preprocessFileLineNumbers "myFile.sqf"; // 0.355 ms
```
```sqf
// myFile.sqf is BIS_fnc_showRespawnMenu
loadFile "myFile.sqf"; // 0.3516 ms
preprocessFile "myFile.sqf"; // 2.75 ms
preprocessFileLineNumbers "myFile.sqf"; // 2.73 ms
```
```sqf
// myFile.sqf is a missing file
loadFile "myFile.sqf"; // 0.692 ms
preprocessFile "myFile.sqf"; // 0.6225 ms
preprocessFileLineNumbers "myFile.sqf"; // 0.6225 ms
```
> [!IMPORTANT]
> The comparison of [loadFile](../commands/loadFile.md) with preprocessFile* is not exactly fair as [loadFile](../commands/loadFile.md) doesn't preprocess the file's content.
>
> On the other hand, the loaded file cannot contain any `//` or `/* */` comments nor any [preprocessor instructions](../topics/PreProcessor_Commands.md) (including debug information like line numbers or file information).
#### ● if
```sqf
if (condition) then { /* thenCode */ }; // 0.0011 ms
if (condition) exitWith { /* exitCode */ }; // 0.0014 ms
if (condition) then { /* thenCode */ } else { /* elseCode */ }; // 0.0015 ms
if (condition) then [{ /* thenCode */ }, { /* elseCode */ }]; // 0.0016 ms
```
#### ● if and select
Use `[array] select boolean` instead of the lazy-evaluated [if](../commands/if.md).
```sqf
_result = ["false result", "true result"] select true; // 0.0011 ms
_result = if (true) then { "true result"; } else { "false result"; }; // 0.0017 ms
```
#### ● if and switch
```sqf
_result = call {
if (false) exitWith {};
if (false) exitWith {};
if (true) exitWith {};
if (false) exitWith {};
if (false) exitWith {};
}; // 0.0032 ms
```
```sqf
_result = switch (true) do {
case (false): {};
case (false): {};
case (true) : {};
case (false): {};
case (false): {};
}; // 0.0047 ms
```
#### ● if else and switch
```sqf
_mode = "killed";
switch _mode do {
case "init": {};
case "killed": {};
case "respawned": {};
}; // 0.0019 ms
```
```sqf
_mode = "killed";
if (_mode == "init") then {} else {
if (_mode == "killed") then {} else {
if (_mode == "respawned") then {};
};
}; // 0.0019 ms
```
#### ● in vs find
```sqf
// String search
"bar" in "foobar" // 0.0008 ms
"foobar" find "bar" > -1 // 0.0012 ms
```
```sqf
// array search - case-sensitive
"bar" in ["foo", "Bar", "bar", "BAR"]; // 0.0012 ms
["foo", "Bar", "bar", "BAR"] find "bar" > -1; // 0.0016 ms
```
#### ● for
The `for..from..to..do` is twice as fast as its alternative syntax, `for..do`.
```sqf
for "_i" from 0 to 10 do { /* forCode */ }; // 0.015 ms
for [{ _i = 0 }, { _i < 100 }, { _i = _i + 1 }] do { /* forCode */ }; // 0.030 ms
```
#### ● forEach vs count vs findIf
Both [forEach](../commands/forEach.md) and [count](../commands/count.md) commands will step through *all* the array elements and both commands will contain reference to current element with the [_x](../topics/Magic_Variables.md#x) variable.
However, [count](../commands/count.md) loop is a little faster than [forEach](../commands/forEach.md) loop, but it does not benefit from the [_forEachIndex](../topics/Magic_Variables.md#foreachindex) variable.
Also, there is a limitation as the code inside [count](../commands/count.md) expects [Boolean](../topics/Boolean.md) or [Nothing](../topics/Nothing.md) while the command itself returns [Number](../topics/Number.md).
This limitation is very important if you try to replace your [forEach](../commands/forEach.md) by [count](../commands/count.md). If you have to add an extra [true](../commands/true.md)/[false](../commands/false.md)/[nil](../commands/nil.md) at the end to make [count](../commands/count.md) work, it will be slower than the [forEach](../commands/forEach.md) equivalent.
```sqf
{ diag_log _x } count [1,2,3,4,5]; // 0.082 ms
{ diag_log _x } forEach [1,2,3,4,5]; // 0.083 ms
```
```sqf
// with an empty array
_someoneIsNear = (allUnits findIf { _x distance [0,0,0] < 1000 }) != -1; // 0.0046 ms
_someoneIsNear = { _x distance [0,0,0] < 1000 } count allUnits > 0; // 0.0047 ms <
_someoneIsNear = {
if (_x distance [0,0,0] < 1000) exitWith { true };
false
} forEach allUnits; // 0.0060 ms
```
```sqf
// with a 30 items array
_someoneIsNear = (allUnits findIf { _x distance [0,0,0] < 1000 }) != -1; // 0.0275 ms
_someoneIsNear = { _x distance [0,0,0] < 1000 } count allUnits > 0; // 0.0645 ms <
_someoneIsNear = {
if (_x distance [0,0,0] < 1000) exitWith { true };
false
} forEach allUnits; // 0.0390 ms
```
#### ● findIf
[findIf](../commands/findIf.md) stops array iteration as soon as the condition is met.
```sqf
[0,1,2,3,4,5,6,7,8,9] findIf { _x == 2 }; // 0.0050 ms
{ if (_x == 2) exitWith { _forEachIndex; }; } forEach [0,1,2,3,4,5,6,7,8,9]; // 0.0078 ms
_quantity = { _x == 2 } count [0,1,2,3,4,5,6,7,8,9]; // 0.0114 ms
```
#### ● format vs str
```sqf
str 33; // 0.0016 ms
format ["%1", 33]; // 0.0022 ms
```
#### ● + vs format vs joinString
non-[String](../topics/String.md) data:
```sqf
[33, 45, 78] joinString ""; // 0.0052 ms - no length limit
format ["%1%2%3", 33, 45, 78]; // 0.0054 ms - limited to ~8Kb
str 33 + str 45 + str 78; // 0.0059 ms - no length limit
```
[String](../topics/String.md) data:
```sqf
["str1", "str2", "str3"] joinString ""; // 0.0015 ms - no length limit
format ["%1%2%3", "str1", "str2", "str3"]; // 0.0015 ms - limited to ~8Kb
"str1" + "str2" + "str3"; // 0.0012 ms - no length limit
```
#### ● private
Direct declaration (`private _var = value`) is faster than declaring *then* assigning the variable.
```sqf
private _a = 1;
private _b = 2;
private _c = 3;
private _d = 4;
// 0.0023 ms
```
```sqf
private ["_a", "_b", "_c", "_d"];
_a = 1;
_b = 2;
_c = 3;
_d = 4;
// 0.0040 ms
```
However, if you have to reuse the same variable in a loop, external declaration is faster.
The reason behind this is that a declaration in the loop will create, assign and delete the variable in each loop.
An external declaration creates the variable only once and the loop only assigns the value.
```sqf
private ["_a", "_b", "_c", "_d"];
for "_i" from 1 to 10 do
{
_a = 1; _b = 2; _c = 3; _d = 4;
};
// 0.0195 ms
```
```sqf
for "_i" from 1 to 10 do
{
private _a = 1; private _b = 2; private _c = 3; private _d = 4;
};
// 0.0235 ms
```
#### ● isNil
```sqf
isNil "varName"; // 0.0007 ms
isNil { varName }; // 0.0012 ms
```
#### ● isEqualType and typeName
[isEqualType](../commands/isEqualType.md) is much faster than [typeName](../commands/typeName.md)
```sqf
"string" isEqualType 33; // 0.0006 ms
typeName "string" == typeName 33; // 0.0018 ms
```
#### ● isEqualTo and count
```sqf
// with a items array
allUnits isEqualTo []; // 0.0040 ms
count allUnits == 0; // 0.0043 ms
```
#### ● select and param
```sqf
[1,2,3] select 0; // 0.0008 ms
[1,2,3] param [0]; // 0.0011 ms
```
#### ● createSimpleObject vs createVehicle
```sqf
// createSimpleObject is over 43× faster than createVehicle!
deleteVehicle createSimpleObject ["a3\structures_f_mark\vr\shapes\vr_shape_01_cube_1m_f.p3d", [0,0,0]]; // ~0.08 ms
deleteVehicle createSimpleObject ["Land_VR_Shape_01_cube_1m_F", [0,0,0]]; // ~3.2 ms
deleteVehicle createVehicle ["Land_VR_Shape_01_cube_1m_F", [0,0,0], [], 0, "CAN_COLLIDE"]; // ~2.7 ms
deleteVehicle createVehicle ["Land_VR_Shape_01_cube_1m_F", [0,0,0], [], 0, "NONE"]; // ~78 ms
```
#### ● objectParent and vehicle
```sqf
isNull objectParent player; // 0.0013 ms
vehicle player == player; // 0.0022 ms
```
#### ● nearEntities and nearestObjects
[nearEntities](../commands/nearEntities.md) is much faster than [nearestObjects](../commands/nearestObjects.md) given on range and amount of objects within the given range.
If range is over 100 meters it is highly recommended to use [nearEntities](../commands/nearEntities.md) over [nearestObjects](../commands/nearestObjects.md).
```sqf
// tested with a NATO rifle squad amongst solar power plant panels on Altis at coordinates [20762,15837]
getPosATL player nearEntities [["CAManBase"], 50]; // 0.0075 ms
nearestObjects [getPosATL player, ["CAManBase"], 50]; // 0.0145 ms
```
> [!IMPORTANT]
> [nearEntities](../commands/nearEntities.md) only searches for [alive](../commands/alive.md) objects and on-foot soldiers.
>
> In-vehicle units, killed units, destroyed vehicles, static objects and buildings will be ignored.
#### ● Global Variables vs Local Variables
If you need to use global variable repeatedly in a loop, copy its value to local variable and use local variable instead:
```sqf
SomeGlobalVariable = [123];
for "_i" from 1 to 100 do
{
SomeGlobalVariable select 0;
};
// 0.13 ms
```
is noticeably slower than
```sqf
SomeGlobalVariable = [123];
private _var = SomeGlobalVariable;
for "_i" from 1 to 100 do
{
_var select 0;
};
// 0.08 ms
```
#### ● Config path delimiter
`>>` is slightly faster than `/` when used in config path with [configFile](../commands/configFile.md) or [missionConfigFile](../commands/missionConfigFile.md).
```sqf
configFile >> "CfgVehicles"; // 0.0019 ms
configFile / "CfgVehicles"; // 0.0023 ms
```
> [!NOTE]
> A config path can be stored in a variable for later use, saving CPU time: `_cfgVehicles = configFile >> "CfgVehicles"`.
#### ● getPos* and setPos*
```sqf
getPosWorld // 0.0015 ms
getPosASL // 0.0016 ms
getPosATL // 0.0016 ms
getPosASLW // 0.0023 ms
getPos // 0.0030-0.0300 ms; performance depends on where this command is used - see its documentation
position // same as getPos
getPosVisual // same as getPos
visiblePosition // same as getPos
```
```sqf
setPosWorld // 0.0060 ms
setPosASL // 0.0060 ms
setPosATL // 0.0060 ms
setPos // 0.0063 ms
setPosASLW // 0.0068 ms
setVehiclePosition // 0.0077 ms with "CAN_COLLIDE"
// 0.0390 ms with "NONE"
```
#### ● toLower/toUpper vs toLowerANSI/toUpperANSI
```sqf
// _myString is a 100 chars "aAaAaA(…)" string
toLowerANSI _myString; // 0.0006 ms
toLower _myString; // 0.0016 ms
toUpperANSI _myString; // 0.0006 ms
toUpper _myString; // 0.0016 ms
```
### Equivalent Data Structures Performance
#### Key-Value Data Structures
```sqf
private _hashMap = createHashMapFromArray [["id", 123], ["name", "player name"], ["unit", player]]; // since Arma 3 v2.02
private _goodFormat = [["id", "name", "unit"], [123, "player name", player]];
private _slowFormat = [["id", 123], ["name", "player name"], ["unit", player]];
```
```sqf
private _name = _hashMap get "name"; // 0.0018ms
// this takes 0.0038ms:
private _index = _goodFormat select 0 find "name"; // loop in engine
private _name = _goodFormat select 1 select _index;
// this takes 0.0116ms:
private _index = _slowFormat findIf { _x select 0 == "name" }; // loop in script
private _name = _slowFormat select _index select 1;
```
> [!NOTE]
> Database Functions use a slow format.
### Conversion From Earlier Versions
Each iteration of Bohemia games (Operation Flashpoint, Armed Assault, Arma 2, Take On Helicopters, Arma 3) brought their own new commands, especially Arma 2 and Arma 3.
For that, if you are converting scripts from older versions of the engine, the following aspects should be reviewed.
#### Loops
- [forEach](../commands/forEach.md) loops, depending on the situation, can be replaced by:
- [apply](../commands/apply.md)
- [count](../commands/count.md)
- [findIf](../commands/findIf.md)
- [select](../commands/select.md)
#### Array Operations
- **Adding an item:** `myArray + [element]` and `myArray set [count myArray, element]` have been replaced by [pushBack](../commands/pushBack.md)
- **Selecting a random item:** [BIS_fnc_selectRandom](../functions/BIS_fnc_selectRandom.md) has been replaced by [selectRandom](../commands/selectRandom.md)
- **Removing items:** `myArray set [1, objNull]; myArray - [objNull]` has been replaced by [deleteAt](../commands/deleteAt.md) and [deleteRange](../commands/deleteRange.md)
- **Concatenating:** `myArray = myArray + [element]` has been *reinforced* with [append](../commands/append.md): if you don't need the original array to be modified, use [+](../commands/~2B.md)
- **Comparing:** use [isEqualTo](../commands/isEqualTo.md) instead of [BIS_fnc_areEqual](../functions/BIS_fnc_areEqual.md)
- **Finding common items:** [in](../commands/in.md) [forEach](../commands/forEach.md) loop has been replaced by [arrayIntersect](../commands/arrayIntersect.md)
- **Condition filtering:** [forEach](../commands/forEach.md) can be replaced by [select](../commands/select.md) (alternative syntax)
```sqf
result = (arrayOfNumbers select { _x % 2 == 0 }); // 1.55 ms
```
```sqf
result = [];
{
if (_x % 2 == 0) then { result pushBack _x; };
} forEach arrayOfNumbers; // 2.57 ms
```
#### Vector Operations
- [BIS_fnc_vectorMultiply](../functions/BIS_fnc_vectorMultiply.md) has been replaced by [vectorMultiply](../commands/vectorMultiply.md) (at least 6x faster)
- [BIS_fnc_vectorDivide](../functions/BIS_fnc_vectorDivide.md) too, to an extent (see [its page](../functions/BIS_fnc_vectorDivide.md) for more information)
```sqf
private _vector = [102, 687, 1543];
private _factor = 53;
_vector vectorMultiply _factor; // 0.0028 ms
[_vector, _factor] call BIS_fnc_vectorMultiply; // 0.0145 ms
_vector vectorMultiply (1 / _factor); // 0.003 ms - but beware of 0 divisor
[_vector, _factor] call BIS_fnc_vectorDivide; // 0.017 ms
```
#### String Operations
[String](../topics/String.md) manipulation has been simplified with the following commands:
- alternative syntax for [select](../commands/select.md): `string select index`
- [toArray](../commands/toArray.md) and [toString](../commands/toString.md) have been *reinforced* with [splitString](../commands/splitString.md) and [joinString](../commands/joinString.md)
#### Number Operations
- [BIS_fnc_linearConversion](../functions/BIS_fnc_linearConversion.md) has been replaced by [linearConversion](../commands/linearConversion.md). The command is **9 times faster**.
- [BIS_fnc_selectRandomWeighted](../functions/BIS_fnc_selectRandomWeighted.md) has been replaced by [selectRandomWeighted](../commands/selectRandomWeighted.md). The command is **7 times faster**.
#### Type Comparison
- [typeName](../commands/typeName.md) has been more than *reinforced* with [isEqualType](../commands/isEqualType.md).
#### Multiplayer
- [BIS_fnc_MP](../functions/BIS_fnc_MP.md) has been replaced by [remoteExec](../commands/remoteExec.md) and [remoteExecCall](../commands/remoteExecCall.md) and internally uses them. Use the engine commands from now on!
> [!NOTE]
> See also [Multiplayer Scripting](../topics/Multiplayer_Scripting.md).
#### Parameters
- [BIS_fnc_param](../functions/BIS_fnc_param.md) has been replaced by [param](../commands/param.md) and [params](../commands/params.md). The commands are approximately **14 times** faster. Use them!
Source: [BI Community Wiki — Code Optimisation](https://community.bistudio.com/wiki/Code_Optimisation) (revision 378687).