---
name: "Multiplayer Scripting"
type: topic
aliases: ["JIP", "Join In Progress", "Locality in Multiplayer", "Multiplayer scripting"]
source: https://community.bistudio.com/wiki/Multiplayer_Scripting
revid: 376938
updated: 2025-12-31T22:33:57Z
---
# Multiplayer Scripting
This page aims to explain notions and specificities of [Multiplayer Scripting](../topics/Multiplayer_Scripting.md) and its differences with Singleplayer Scripting.
It features three parts:
1. [#Notions and general knowledge](../topics/Multiplayer_Scripting.md#notions-and-general-knowledge)
1. [#Structuring Multiplayer code](../topics/Multiplayer_Scripting.md#structuring-multiplayer-code)
1. [Testing locally](../topics/Multiplayer_Scripting.md#testing-locally)
## Notions and general knowledge
### The basics
- In Multiplayer, players are connected to a **server**.
- The server is a machine that distributes information among clients, such as unit positions, vehicle speeds, etc.
- The server can be either a dedicated machine, or hosted by a player; in the latter it means the server can have a [player](../commands/player.md) unit.
- A machine connected to a server is called a **client**.
- Clients can join a mission *after* it started: they are considered "[JIP](../topics/Multiplayer_Scripting.md#join-in-progress)" and scripting should be adapted to them. See the [#Join In Progress](../topics/Multiplayer_Scripting.md#join-in-progress) chapter for more information.
> [!NOTE]
> In Singleplayer, the game acts as a player-hosted server ([isServer](../commands/isServer.md) returns true).
> [!WARNING]
> Some Multiplayer commands do **not** work in Singleplayer, such as [netId](../commands/netId.md)!
>
> The other way around, some Singleplayer commands do not work in Multiplayer (e.g [setAccTime](../commands/setAccTime.md)).
### Locality
#### Definitions
- **LOCAL** is an attribute for the machine where the command/script/function is executed or the AI calculated.
- to check if an argument is local, use the [local](../commands/local.md) command
- **REMOTE** means **non local** - on another machine. All player-controlled soldiers are remote units to a dedicated server, for example.
- to check if an argument is remote, simply use `not local _myObject`
- commands arguments and effects can be either **local** or **global**:
| | |
|---|---|
| Local Argument | a **local** argument means an argument that is processed on the machine where the command is executed |
| Global Argument | a **global** argument means any argument, even a remote one |
| Local Effect | a **local** effect means that the effect will only happen on the machine where the command is executed |
| Global Effect | a **global** effect means that all the computers will receive it |
| Server Execution | **server exec** means that the command or function has to be executed on the server machine, either mission host or dedicated server |
> [!NOTE]
> See also:
> - Scripting Commands: Local Effect
> - Scripting Commands: Global Effect
> - Scripting Commands: Server Execution
> - Functions: Local Effect
> - Functions: Global Effect
> - Functions: Server Execution
#### Different machines and how to target them
> [!NOTE]
> - For obvious reasons, a server cannot be [JIP](../topics/Multiplayer_Scripting.md#join-in-progress).
> - Use [didJIP](../commands/didJIP.md) to determine if a client joined during the game.
| Scripting Commands | Server | Player client | Headless client | Note | |
|---|---|---|---|---|---|
| Dedicated | Player-Hosted | | | | |
| ```sqf
isDedicated
``` | ✓ | ✗ | ✗ | ✗ | Dedicated server |
| ```sqf
hasInterface && isServer
``` | ✗ | ✓ | ✗ | ✗ | Player server |
| ```sqf
hasInterface && not isServer
``` | ✗ | ✗ | ✓ | ✗ | Player client |
| ```sqf
not hasInterface && not isDedicated
``` | ✗ | ✗ | ✗ | ✓ | Headless client |
| ```sqf
isServer
``` | ✓ | ✓ | ✗ | ✗ | Any server |
| ```sqf
hasInterface
``` | ✗ | ✓ | ✓ | ✗ | Any player |
| Miscellaneous | | | | | |
| ```sqf
not isServer
``` | ✗ | ✗ | ✓ | ✓ | All server clients, including headless clients, but excluding player host |
| ```sqf
not isDedicated
``` | ✗ | ✓ | ✓ | ✓ | Everything but a dedicated server |
| ```sqf
not hasInterface
``` | ✓ | ✗ | ✗ | ✓ | Headless clients and dedicated server |
**For an extended version for all games, click**
> [!NOTE]
> Before Operation Flashpoint v1.99 and the backport of [isServer](../commands/isServer.md), the server could be identified by placing a [Game Logic](../topics/Object.md) in the editor (that would always remain local to the server), then using the following: `local myLogic`.
| Targeted machine | Operation Flashpoint | Armed Assault | Arma 2 | Arma 3 |
|---|---|---|---|---|
| **Dedicated Server**
A server without a human player behind it | ```sqf
isServer && isNull player
``` | ```sqf
isServer && isNull player
``` | ```sqf
isDedicated
``` | ```sqf
isDedicated
``` |
| **Player Server**
A server hosted by a player | ```sqf
isServer && not isNull player
``` | ```sqf
isServer && not isNull player
``` | ```sqf
isServer && not isDedicated
``` | ```sqf
hasInterface && isServer
``` |
| **Server**
Any server, dedicated or hosted | ```sqf
isServer
``` | ```sqf
isServer
``` | ```sqf
isServer
``` | ```sqf
isServer
``` |
| **Player Client**
A player connected since the lobby | ```sqf
not isServer && not isNull player
``` | ```sqf
not isServer && not isNull player
``` | ```sqf
not isServer && not isNull player
``` | ```sqf
hasInterface && not isServer
``` |
| **JIP Player Client**
A player connected in the middle of a mission | N/A | ```sqf
not isServer && isNull player
``` | ```sqf
not isServer && isNull player
``` | ```sqf
hasInterface && didJIP
``` |
| **Headless Client**
A client without a human player behind it
(used to offload server calculations) | colspan="3" N/A | ```sqf
not hasInterface && not isServer
``` | | |
| **JIP Headless Client**
Headless client connected during the ongoing mission | colspan="3" N/A | ```sqf
not hasInterface && not isServer && didJIP
``` | | |
- If you want to know if the current machine is a server (Dedicated Server or Player Server), use [isServer](../commands/isServer.md).
- If you want to know if the current machine has a player (Player Server included), use [hasInterface](../commands/hasInterface.md).
> [!NOTE]
> **Arma 3:** Since Arma 3, a server-only init file is available: **initServer.sqf** (see [Event Scripts](../topics/Event_Scripts.md))
> [!NOTE]
> **Arma 3:** **[BIS_fnc_getNetMode](../functions/BIS_fnc_getNetMode.md)** can be used to have a string value representing the local machine status ("DedicatedServer", "Server", "HeadlessClient", "Client", "SinglePlayer" ).
>
> This function doesn't make the JIP distinction and should be used along [didJIP](../commands/didJIP.md).
#### General information about locality
- about [player](../commands/player.md):
- a [player](../commands/player.md)'s unit is **always** local to the (human) player's machine
- a dedicated server doesn't have a [player](../commands/player.md) unit (`isNull player` returns [true](../commands/true.md))
- to know if a certain unit is *a* player, use [isPlayer](../commands/isPlayer.md)
- groups and AI:
- an AI group with a player-leader will be local to the player's computer
- a subordinate player being in a player-lead group will remain local to its computer (see bulletpoint #1)
- objects:
- a driven vehicle is always local to the machine of its driver (not the commander's, not the gunner's)
- terrain objects (buildings, vegetation, roads etc.) are local everywhere (`local nearestBuilding player` returns [true](../commands/true.md) on every client)
- editor-placed objects and empty vehicles are local to the server
- editor-placed **triggers** are created on every machine unless specified otherwise ("Server Only" Eden Editor option ticked)
- units created with [createUnit](../commands/createUnit.md) will be local to the computer that issued the command
- objects and vehicles created with [createVehicle](../commands/createVehicle.md) will be local to the computer that issued the command
#### Locality changes
- if the player-leader dies, the AI is transferred to the machine where the new leader is local (server in case of AI, client in case of another player)
- [joining](../commands/join.md) AI units will change locality to the new leader's computer
- locality will change from server to client when a player gets in an empty vehicle
- locality can also change in the event of a Team Switch or usage of [selectPlayer](../commands/selectPlayer.md)
> [!NOTE]
> **Arma 3:** Since Arma 3 the ["Local" Event Handler](../topics/Event_Handlers.md#local) triggers when an object's locality is changed.
#### Code examples
| Code | Argu-ments | Effect | Description |
|---|---|---|---|
| ```sqf
remoteUnit setDamage 1;
``` | Global Argument | Global Effect | Any unit (local or remote) will die, and all the computers will know |
| ```sqf
localUnit addMagazine "30Rnd_556x45_STANAG";
``` | Local Argument | Global Effect | Only a local unit can have its inventory edited with this command, but all the machines will be notified: if a player looks into the *localUnit* inventory, the added magazine will be there |
| ```sqf
remoteUnit setFace "Miller";
``` | Global Argument | Local Effect | Any unit (local or remote) can get its face changed, but the new face will not be propagated through the network. Only the local machine's player will see the effect of the command
> [!NOTE]
> This command should ideally be **executed on every machine**, for example with:
>
> ```sqf
> [remoteUnit, "Miller"] remoteExec ["setFace", 0, true];
> ```
>
> See the [#Remote Execution](../topics/Multiplayer_Scripting.md#remote-execution) chapter for more information. |
| ```sqf
localCamera cameraEffect ["Internal", "Back"];
``` | Local Argument | Local Effect | Only a local camera can be entered, and of course only the local machine will see through this camera |
### Network ID
Network IDs identify machines and network objects. They can be used to target proper machines with remote execution; see the [#Remote Execution](../topics/Multiplayer_Scripting.md#remote-execution) chapter for more information.
> [!WARNING]
> **A machine ID** ([ownerID](../commands/owner.md)) is not to be confused with **an object's network ID** ([netId](../commands/netId.md)).
#### Machine network ID
Every machine, including the server, has a **network ID**.
A server always has an ID of **2**, every new client has the next number (the first client will be number **3**, second client number **4**, etc.)
- To get the current machine's ID, use [clientOwner](../commands/clientOwner.md).
- To get the machine ID of an object's owner, use [owner](../commands/owner.md) *object* (MP only).
- To get the machine ID of a group's owner, use [groupOwner](../commands/groupOwner.md) *object* (MP only).
> [!NOTE]
> **0** and **1** are special values:
> - **0** means **everyone** (including the server)
> - **1** means **current machine** but **is not implemented** and should **not** be used.
#### Object network ID
Every object synchronised through the network has a network ID, shortened to **netId**.
- To get an object's netId, use [netId](../commands/netId.md) (MP only). **SP & MP variant:** [BIS_fnc_netId](../functions/BIS_fnc_netId.md)
- To get an object from a netId, use [objectFromNetId](../commands/objectFromNetId.md) (MP only). **SP & MP variant:** [BIS_fnc_objectFromNetId](../functions/BIS_fnc_objectFromNetId.md)
- To get a group from a netId, use [groupFromNetId](../commands/groupFromNetId.md) (MP only). **SP & MP variant:** [BIS_fnc_groupFromNetId](../functions/BIS_fnc_groupFromNetId.md)
### Sending information across network
#### Remote Execution
Since Arma 3 v1.50, [remoteExec](../commands/remoteExec.md) and [remoteExecCall](../commands/remoteExecCall.md) efficient engine network commands are available:
```sqf
"Message to everyone, including JIP players!" remoteExec ["hint", 0, true];
```
See [Arma 3: Remote Execution](../topics/Remote_Execution.md) for more information.
Arma 3 alpha introduced [BIS_fnc_MP](../functions/BIS_fnc_MP.md) (**obsolete** since Arma 3 v1.50, use the above version):
```sqf
["Message to everyone, including JIP players!", "hint", true, true] call BIS_fnc_MP; // obsolete since Arma 3 v1.50, use remoteExec or remoteExecCall
```
Arma 2 introduced the Arma 2: Multiplayer Framework (not present in Arma 3):
```sqf
// having the Functions module placed in the editor
waitUntil { not isNil "BIS_MPF_InitDone"; };
[nil, nil, rHINT, "Message to everyone!"] call RE;
```
#### PublicVariable commands
PublicVariable commands allow to send **global** variables to specified machines.
- Network reception is guaranteed
- Short variable names should be used for network performance
- These commands shouldn't be used intensely for the same reason
| Command | Effect | [JIP](../topics/Multiplayer_Scripting.md#join-in-progress) synchronised |
|---|---|---|
| [publicVariable](../commands/publicVariable.md) | Set/update a variable value from the local machine to all the other machines (including server) | ✓ |
| [publicVariableServer](../commands/publicVariableServer.md) | Set/update a variable value **from a client to the server** | ✗ |
| [publicVariableClient](../commands/publicVariableClient.md) | Set/update a variable value **from the local machine** (not necessarily the server) **to a specific client** | ✗ |
##### How it works
The server has the variable `ABC_Score` to broadcast:
```sqf
ABC_Score = 5; // sets the value
publicVariable "ABC_Score" // publishes the variable (do not forget the quotes!)
```
This sends the variable name and value to the clients.
- If the variable is not yet declared on their machine, it will declare it as well.
- If the variable already exists, **the value is overridden** by the server's value.
- If the variable changes again on the server, it has to be manually [publicVariable](../commands/publicVariable.md)'d once again!
- A [JIP](../topics/Multiplayer_Scripting.md#join-in-progress) player will synchronise **server's** [publicVariable](../commands/publicVariable.md)'d variables **before** executing **init.sqf**. See [Initialisation Order](../topics/Initialisation_Order.md) for more information.
- A JIP player will **not** synchronise [publicVariableClient](../commands/publicVariableClient.md)-received variables after he disconnects/reconnects. Only server-known public variables sent with [publicVariable](../commands/publicVariable.md) will be synchronised.
#### setVariable command
Available since Arma 2, the **public** version of the [setVariable](../commands/setVariable.md) command (alternative syntax) allows you to store a variable into an object and spread this variable across the network.
> [!NOTE]
> **Arma 3:** In Arma 3 it is possible to broadcast the [nil](../commands/nil.md) value, thus deleting the variable from the target.
### Player connection events
The following commands will execute given code when a player is connecting or disconnecting. This code will run for players connecting in the lobby **and** for [JIP](../topics/Multiplayer_Scripting.md#join-in-progress) players!
- ["PlayerConnected" mission Event Handler](../topics/Mission_Event_Handlers.md#playerconnected)
- ["PlayerDisconnected" mission Event Handler](../topics/Mission_Event_Handlers.md#playerdisconnected)
> [!NOTE]
> Before Arma 3 v1.58, use [BIS_fnc_addStackedEventHandler](../functions/BIS_fnc_addStackedEventHandler.md) for [onPlayerConnected](../commands/onPlayerConnected.md)/[onPlayerDisconnected](../commands/onPlayerDisconnected.md).
### Client state
A client state is the client's connection state. It can be obtained with [getClientState](../commands/getClientState.md) and [getClientStateNumber](../commands/getClientStateNumber.md) commands on both server and clients.
| [getClientStateNumber](../commands/getClientStateNumber.md) | [getClientState](../commands/getClientState.md) | Description |
|---|---|---|
| 0 | "NONE" | No client (or singleplayer) |
| 1 | "CREATED" | Client is created |
| 2 | "CONNECTED" | Client is connected to server, message formats are registered |
| 3 | "LOGGED IN" | Identity is created |
| 4 | "MISSION SELECTED" | Mission is selected |
| 5 | "MISSION ASKED" | Server was asked to send / not send mission |
| 6 | "ROLE ASSIGNED" | Role was assigned (and confirmed) |
| 7 | "MISSION RECEIVED" | Mission received |
| 8 | "GAME LOADED" | Island loaded, vehicles received |
| 9 | "BRIEFING SHOWN" | Briefing was displayed |
| 10 | "BRIEFING READ" | Ready to play mission |
| 11 | "GAME FINISHED" | Game was finished |
| 12 | "DEBRIEFING READ" | Debriefing read, ready to continue with next mission |
### Join In Progress (Armed Assault v1.00)
**Join In Progress** (JIP) is the ability for a player to connect while a game is running, unlike in Operation Flashpoint where one had to wait for the game to be over.
It was introduced in on Xbox and Armed Assault on PC.
A player that joined in progress will be referred to as **JIP player**.
> [!NOTE]
> To disable JIP on a server:
> - the server admin can disable playable slots on the role selection screen
> - the mission designer can [disable AI](../topics/Description.ext.md#disabledai) within mission config
> However, JIP remains available if respawn is enabled in the mission.
#### JIP Synchronisation
A JIP player will have a lot of information synchronised ([publicVariable](../commands/publicVariable.md)'d and [setVariable](../commands/setVariable.md) server variables for example) by the game **before** accessing the mission itself; see below:
| Information | Arma 1 | Arma 2 | Arma 3 |
|---|---|---|---|
| date/time | ✓ | ✓ | ✓ |
| date/time + [setDate](../commands/setDate.md)/[skipTime](../commands/skipTime.md) | ✗ | ✗ | ✓ |
| weather ([overcast](../commands/overcast.md), [fog](../commands/fog.md)) | ✗ | ✓ | ✓ |
| weather + [setOvercast](../commands/setOvercast.md)/[setFog](../commands/setFog.md)/[setRain](../commands/setRain.md)/[setLightnings](../commands/setLightnings.md) | ✗ | ✗ | ✓ |
| time passed since mission start ([time](../commands/time.md) command) | | | ✓ |
| [publicVariable](../commands/publicVariable.md)-sent variables ([Number](../topics/Number.md), [String](../topics/String.md), [Structured Text](../topics/Structured_Text.md), [Array](../topics/Array.md), [Code](../topics/Code.md)) | ✓ | ✓ | ✓ |
| [publicVariable](../commands/publicVariable.md)-sent variables ([nil](../commands/nil.md)) | ✗ | ✗ | ✓ |
| [setVariable](../commands/setVariable.md)-assigned variables (when alternative syntax's *public* parameter is set to true) | N/A | ✓ | ✓ |
| [remoteExec](../commands/remoteExec.md)- and [remoteExecCall](../commands/remoteExecCall.md)-executed code if *JIP* prerequisites are met | colspan="2" N/A | ✓ | |
> [!WARNING]
> All the **initialisation fields** code get executed again for **each and every JIP connecting player**.
>
> This means that code with global effect Global Effect (such as [setDamage](../commands/setDamage.md)) **WILL** be re-executed (depending on locality)!
#### Related Commands
- [remoteExec](../commands/remoteExec.md)
- [remoteExecCall](../commands/remoteExecCall.md)
- [didJIP](../commands/didJIP.md)
- [didJIPOwner](../commands/didJIPOwner.md)
- [exportJIPMessages](../commands/exportJIPMessages.md)
- [isRemoteExecutedJIP](../commands/isRemoteExecutedJIP.md)
### See also
- Headless Client
- [Initialisation Order](../topics/Initialisation_Order.md)
- [Arma 3: Remote Execution](../topics/Remote_Execution.md)
## Structuring Multiplayer code
### Responsibilities
- The **server** initialises and works with **variables**
- A connecting or connected **player-client** gets the mission data from the server
- Once an objective is reached, **the server tells the players** via [remoteExec](../commands/remoteExec.md)/[remoteExecCall](../commands/remoteExecCall.md), [publicVariable](../commands/publicVariable.md) or [setVariable](../commands/setVariable.md)
- Players can get their client-side UI code triggered by the server
See [this earlier chapter](../topics/Multiplayer_Scripting.md#different-machines-and-how-to-target-them) to know how to target specific machines.
#### Server
The **Server** must be considered as the one ruler of the mission. He is the game's referee and all the decisions should come from it. All the values on the server should be considered as **true**.
Consider the server as a powerful machine where you can put all the mission conditions and heavy scripting on.
In case of a very heavy mission, the server can be assisted by Headless Clients (this involves a per-mission specific design).
Server-side code must gather or wait all the variables (potentially from client-side scripts and [publicVariableServer](../commands/publicVariableServer.md)) and take and broadcast its decisions accordingly using [publicVariable](../commands/publicVariable.md).
Server-side code should ideally **not** make any reference to a [player](../commands/player.md) variable considering a server can potentially be **dedicated**, unless you want to force this mission to be player-hosted (such as Arma 2's campaign).
> [!NOTE]
> Use [allPlayers](../commands/allPlayers.md), [BIS_fnc_listPlayers](../functions/BIS_fnc_listPlayers.md), [playableUnits](../commands/playableUnits.md) (and [switchableUnits](../commands/switchableUnits.md) for SP compatibility) to refer to players.
#### Client
The **Client** must be considered as an average machine that can leave the game at any moment.
**No mission-vital code must be executed on its side** and **no decisions must be taken client-side**.
Again, **one must expect that any client can disconnect at any moment**.
The client executes all the (local) UI code (Post Process Effects, Dialogs, etc.)
The player's machine should not deal with a great piece of code.
> [!IMPORTANT]
> Do not forget that a server **can** be a player, and therefore should execute player code in that case.
The proper way to check for player-side condition is
```sqf
if (hasInterface) then { /* (...) */ };
```
Note that the following example is **incorrect**:
```sqf
if (isServer) then
{
// ...
}
else // WRONG: a server CAN be a player
{
// ...
};
```
### Code writing
The usual four steps of coding are the following:
- Think it well
- If you cannot figure out how to write your code, say what you want to do out loud or write it down in your language, then replace it by code little by little.
- Make it work
- use the -showScriptErrors startup parameter to see your code errors.
- Make it readable
- name your variables properly, as if you had to give it to someone that should get it without the need of explaining
- Optimise then
- use more performance-friendly commands, reduce your search radius and loop frequencies once everything works.
See [Code Optimisation#Rules](../topics/Code_Optimisation.md#rules) for advices and more information.
### See also
- [Event Scripts](../topics/Event_Scripts.md)
- [Code Optimisation](../topics/Code_Optimisation.md)
## Local Multiplayer Testing
To ensure all cases, your mission should ideally work properly:
- in Singleplayer
- in Player-hosted Multiplayer
- in a Dedicated Server-hosted game
The following chapters explain how to mimic multiple clients on one computer. Of course, nothing prevents you from inviting friends to play your mission and report bugs!
### Dedicated Server
To properly test MP scripting locality issues, it is recommended to run a **dedicated server** and connect with **two** clients. In order to do so:
- In your server executable's server.cfg:
```cpp
loopback = true; // force LAN-only server
kickDuplicate = 0; // disable duplicate Arma kick
// needed in case of Headless Client test only
headlessClients[] = { "127.0.0.1" };
localClient[] = { "127.0.0.1" };
```
- Run the game twice from Steam and connect each (with `-showScriptErrors` flag)
- If you use one screen for the first client and the other screen for the second client, use `-noPause -window` launcher options. This will not pause render if the window doesn't have focus.
> [!IMPORTANT]
> Be sure to disable BattlEye or it will close any additional instances.
- Try your mission and check for script errors:
- on client's screens and RPT files
- in your server's RPT files
| Pros | Cons |
|---|---|
| - Tests almost all "can go wrong" scenarios
- Can test Headless Clients, persistent server, server restart, admin login/logout | - Misses cases where [isDedicated](../commands/isDedicated.md) is used instead of [isServer](../commands/isServer.md)
- "Big" setup |
### Player-Hosted Server
While this method covers less cases than the [#Dedicated Server Test](../topics/Multiplayer_Scripting.md#dedicated-server-test) method above, this method is faster:
- Open the Arma 3: Launcher and disable BattlEye
- Select the mods that the host will use (if any)
- Launch the game using the `Play`/`Play with Mods` button
- Select the mods that clients will use
- Launch the game again using the `Play`/`Play with Mods` button
- In the first game instance (server), host the mission either through local hosting or with Eden Editor MP mission type launch
- In the second game instance (client), join the session using the MP tab LAN section and entering the mission hosted by the server
| Pros | Cons |
|---|---|
| - Fast setup (with quick modlist support)
- Helps find cases where [isDedicated](../commands/isDedicated.md) is used instead of [isServer](../commands/isServer.md) | - May miss locality issues (code that happens to run on the server because it runs on the server's *client* like e.g [hideObjectGlobal](../commands/hideObjectGlobal.md))
- No headless client testing (this can be solved by using a custom server.cfg) |
### See Also
- Arma 3: Dedicated Server
- server config
Source: [BI Community Wiki — Multiplayer Scripting](https://community.bistudio.com/wiki/Multiplayer_Scripting) (revision 376938).