configClasses

Description

Returns an array of config entries which meet criteria in condition code. Command iterates through all available config sub classes of the given config class. Current looked at config is stored in _x variable (similar to alternative count command implementation). Condition has to return true in order for the looked at config to be added to the resulting array. Slightly faster than configProperties, but doesn't account for config properties or inherited entries.

Important

• The condition code passed to configClasses should only be used for simple filter expressions and nothing more

• Do not use "isClass _x" in the condition. The engine does this check already

• Arma 3 v2.02 brought specific engine optimisations for the following conditions:

  • "true"
  • "getNumber (_x >> 'scope') > 0"

Syntax

Syntax 1

condition configClasses config

Parameters:

• condition: String
• config: Config

Returns: Array of Configs

Syntax 2

since arma3 2.22

configClasses [config, depth, includeInherited, allSubclasses, classNames]

Parameters:

• config: Config - target config
• depth: Number - how many levels of subclasses to go deep
• includeInherited: Boolean - true to look through inherited classes
• allSubclasses: Boolean - true to return all subclasses, false - to return only the last tier.
• classNames: Boolean - (Optional, default: false) when true class names Strings are returned, when false - Configs are returned.

Returns: Array of Configs or Strings, which represent class names.

Examples

Example 1

collect all CfgVehicles configs:

_configs = "true" configClasses (configFile >> "CfgVehicles");

Example 2

Return all classes that can transport 10 and more soldiers:

_transporters = "getNumber (_x >> 'transportSoldier') >= 10" configClasses (configFile >> "CfgVehicles");

Example 3

Return all classes that inherit from 'RscText':

hint str ("inheritsFrom _x == (configFile >> 'RscText')" configClasses configFile);

Example 4

Return children:

configClasses [configFile >> "CfgGroups", 0, true, true, true]
//Returns ["West","East","Indep","Empty"]

See also

Config · configFile · missionConfigFile · configProperties · configHierarchy · BIS_fnc_returnChildren

// create an array of west vehicles and spawn then in front of the player in rows of 5

private ["_cfgArray", "_xPos", "_yPos", "_veh"];

_cfgArray = "( 
    (getNumber (_x >> 'scope') >= 2) && 
    {
        getNumber (_x >> 'side') == 1 && 
        { getText (_x >> 'vehicleClass') in ['Armored', 'Car', 'Air'] }
    }
)" configClasses (configFile >> "CfgVehicles");

_xPos = 0;
_yPos = 0;

{
    _yPos = _yPos + 20;
    _veh = createVehicle [(configName _x), player modelToWorld [_xPos, _yPos, 0], [], 0, "NONE"];
    if (_yPos >= 100) then
    {
        _yPos = 0;
        _xPos = _xPos + 20;
    };
} forEach _cfgArray;

configProperties [_config, "isClass _x", true];

( "true" configClasses (configFile >> "CfgWorlds" >> worldName >> "names" ) ) apply {
    // change each config entry into a location
    nearestLocation [
        getArray ( _x >> "position" ),
        getText ( _x >> "type" )
    ]
};