BIS_fnc_ambientAnim

Description

Play set of ambient animations on given unit. If the unit should react to combat, use BIS_fnc_ambientAnimCombat instead.

Note
Animations can be cancelled using _unit call BIS_fnc_ambientAnim__terminate.

Syntax

[unit, animationSet, equipmentLevel, snapTo, interpolate, attachToLogic] call BIS_fnc_ambientAnim

Parameters:

unit: Object - unit that will play the animations

animationSet: String - the animation set to play. Possible values:


some values are missing due to duplicate results, e.g "STAND" does the same as "STAND1"
- STAND1 - STAND2 - STAND_U1 - STAND_U2 - STAND_U3 - WATCH - WATCH2 - GUARD - LISTEN_BRIEFING - LEAN_ON_TABLE - LEAN	- SIT_AT_TABLE - SIT1 - SIT - SIT3 - SIT_U1 - SIT_U2 - SIT_U3 - SIT_HIGH1 - SIT_HIGH - SIT_LOW - SIT_LOW_U - SIT_SAD1 - SIT_SAD2	- KNEEL - REPAIR_VEH_PRONE - REPAIR_VEH_KNEEL - REPAIR_VEH_STAND - PRONE_INJURED_U1 - PRONE_INJURED_U2 - PRONE_INJURED - KNEEL_TREAT - KNEEL_TREAT2 - BRIEFING - BRIEFING_POINT_LEFT - BRIEFING_POINT_RIGHT - BRIEFING_POINT_TABLE

equipmentLevel: String - the equipment level of the unit. Possible values:
- NONE
- LIGHT
- MEDIUM
- FULL
- ASIS
- RANDOM
snapTo: Object - (Optional, default objNull) the object where the unit will be snapped to
interpolate: Boolean - (Optional, default false) should try to interpolate into the ambient animation. Works only for some default stances
attachToLogic: Boolean - (Optional, default true) true to attach the unit to the created logic object, forcing it in one position

Returns: Nothing

Examples

Example 1

[player, "STAND1", "ASIS"] call BIS_fnc_ambientAnim;

Example 2

// will search for a chair within 2 meters around the unit and will place the unit on it
[_unit, "SIT", "NONE"] call BIS_fnc_ambientAnim;

Community notes

PierreMGI2016-02-19

In 3den editor, place a blufor unit (B_soldier_A_F) near a camping chair (land_campingChair_V2_F).

In init field of the unit:

[this, "SIT2"] call BIS_fnc_ambientAnim;
0 = this spawn {
    waitUntil { behaviour _this == "combat"};
    _this call BIS_fnc_ambientAnim__terminate;
};

When this unit is aware of a threat, he will quit the "ambient animation" and will able to return fire.

Note: BIS_fnc_ambientAnimCombat doesn't need this script but the list of animations is limited.

PierreMGI2016-08-08

To make this command working in MP (hosted server tested)

[this, "SIT2"] call BIS_fnc_ambientAnim; // wrong! the first JIP will throw the unit to position [0,0,0]
if (isServer) then { [this, "SIT2"] call BIS_fnc_ambientAnim; }; // wrong! only player located on server will see the animation
if (local this) then { [this, "SIT2"] call BIS_fnc_ambientAnim; }; // OK, best way
if (isServer) then { [this, "SIT2"] remoteExecCall ["BIS_fnc_ambientAnim"]; }; // OK

Icaruk2016-08-11

Be careful using this function multiple times on MP, it creates a Logic using createUnit (which is global).

If you use it on 20 units, 20 additional logics will be created.