createDiaryRecord

Description

Creates a Diary entry. Supported tags and their parameters:

Tag	Options	Example
img	- image: String - path to image. When present, any element with it will be displayed as image. - width: Number - image width in pixels. - height: Number - image height in pixels. - Arma 3 v2.10 title: String - tooltip to show on mouse over image - Arma 3 v2.10 src: String - alternative to 'image' > [!NOTE] > Arma 3: Maximum width supported seems to be 370 pixels as a wider image will be cut off. Height should be calculated with the aspect ratio of the image. `height = 370; ratio = 16/9; height = width / ratio;`	`html <img image="picture.paa" width="128" height="64" />` Since Arma 3 v2.10: `html <img src="picture.paa" width="128" height="64" title="this is an image" />`
font	- color: String - HTML color in format #aarrggbb or #rrggbb - size: Number - font height in pixels (default: 14) - face: String - font type (see Fonts)	`html <font color="#FF00FF" size="16" face="LucidaConsoleB">Hello there</font>`
br	N/A	`html Line 1<br />Line 2`
marker	- name: String - marker name	`html <marker name="respawn_west">Respawn point</marker>`
execute	- expression: String - executed code	`html <execute expression="player setDamage 1">Die!</execute>`
executeClose	- expression: String - executed code, diary is closed afterwards	`html <executeClose expression="player setDamage 1">Die and close</executeClose>`
log	- subject: String - subject name. - record: String - record ID (e.g. "Record6" or "Unit1059524")	`html <log subject="Hello">Get to the "Hello" subject</log>` `html <log subject="Hello" record="Record0">Go to the first record added to "Hello"</log>`
gear	- unit: Number - unit ID	`html <gear unit="123456">Open unit 123456's gear</gear>`
teamSwitch	- unit: Number - unit ID	`html <teamSwitch unit="123456">Switch to unit 123456</teamSwitch>`
kick	- id: Number - unit ID	`html <kick unit="123456">Kick player unit 123456</kick>`
ban	- id: Number - unit ID	`html <ban unit="123456">ban player unit 123456</ban>`
mute	- id: Number - unit ID	`html <mute unit="123456">mute player unit 123456</mute>`
voteadmin	- id: Number - unit ID	`html <voteadmin unit="123456">vote admin unit 123456</voteadmin>`
votekick	- id: Number - unit ID	`html <votekick unit="123456">vote kick player unit 123456</votekick>`
currentTask	- id: Number - task ID - action: String - 'n' or 's' (select)	`html <currentTask id="my_task">get to my_task task</currentTask>`

Note
If the createDiaryRecord command fails, it returns a null record. Before Arma 3 v2.00, isNull did not work with the diary record type and diaryRecordNull did not exist. In order to verify a null record, it is possible to create a variable and compare against it:
private _recordNull = objNull createDiaryRecord [];
private _createdRecord = player createDiaryRecord ["Diary", ["Title", "Description"]];
if (_createdRecord isEqualTo _recordNull) then { hint "Failed"; };

Syntax

player createDiaryRecord [subject, textInfo, task, taskState, showTitle]

Parameters:

player: Object
subject: String
textInfo: String or Array of Strings - can be:
- String - the record's content - its title will be empty
- Array of Strings - format [title, text, icon]:
  - title: String
  - text: String
  - Arma 3 v2.10 icon: String - (Optional) icon to show next to the title
task: Task - (Optional, default taskNull)
taskState: String - (Optional, default "NONE") changes the state of the given task. Can be one of:
- "NONE"
- "CREATED"
- "ASSIGNED"
- "SUCCEEDED"
- "FAILED"
- "CANCELED"
showTitle: Boolean - (Optional, default true) whether or not to show title in the description section as well (since arma3 1.96)

Returns: Diary Record

Examples

Example 1

player createDiaryRecord ["Diary", ["Intel", "Enemy base is on grid <marker name='enemyBase'>161170</marker>"]];

Example 2

player createDiaryRecord ["Diary", "Information gathered.<br /><img image='wellDone_ca.paa' />"];

Example 3

player createDiaryRecord ["Diary", ["Title", "Description"], taskNull, "", false];

Example 4

player createDiaryRecord [
    "Diary",
    ["Font tag", "<font color='#7FFF00' size='30' face='TahomaB'>This will changed text size, colour and font</font>"],
    taskNull,
    "",
    false
];

Example 5

player createDiaryRecord [
    "Diary",
    ["Image", "<img image='\A3\Ui_F_Curator\Data\Logos\arma3_curator_artwork.jpg' width='500' height='800' />"],
    taskNull,
    "",
    false
];

Example 6

player createDiaryRecord ["Diary", ["Linebreak", "Line1<br />Line2<br /><br />Line4"], taskNull, "", false];

Example 7

player createDiaryRecord ["Diary", ["Execute","<execute expression='hint ""Some code"";'>Some text</execute>"], taskNull, "", false];

Example 8

player createDiaryRecord ["Diary", ["ExecuteClose", "<executeClose expression=""hint 'Diary closed';"">Close Diary</executeClose>"], taskNull, "", false];

Community notes

Tankbuster2017-03-24

When adding multiple diary records, be aware that they appear in reverse order. ie the first one you add will appear last and the last one you add will be first.

R3vo2019-06-22

It seems that the task parameter has no effect in Arma 3 because the task entry in the briefing menu is created when the task itself was created.

Honger2022-10-18

<log>, as createDiaryLink, requires declaring both subject and ID of the record belonging to said subject. Otherwise generated text will not be clickable or might open a non-existing record (behaviour similar to clicking on map when viewing Diary).