hintC

Description

Displays a very basic message dialog in the center of the screen. Player control is taken away until "Continue" is pressed. The message dialog can be dragged around on the screen. After "Continue" has been pressed, the content of the hintC is repeated in a normal hint.

Note

In Singleplayer, the game is paused while the message dialog is visible.

Syntax

Syntax 1

hintC message

Parameters:

• message: String

Returns: Nothing

Syntax 2

title hintC message

Parameters:

• title: String - message title
• message: String, Structured Text, Array of Strings or Array of Structured Text

Returns: Nothing

Examples

Example 1

hintC "Press W to move forward";

Example 2

Same as the above in Arma 3 but without second hint displayed:

hintC "Press W to move forward";
hintC_EH = findDisplay 57 displayAddEventHandler ["Unload", {
    _this spawn {
        _this select 0 displayRemoveEventHandler ["Unload", hintC_EH];
        hintSilent "";
    };
}];

Example 3

"Instructions" hintC [
    "Press W to move forward.",
    "Press S to move backwards.",
    "Use the mouse to turn right or left.",
    "Press V for weapon sights."
];

Example 4

Same as the above in Arma 3 but without second hint displayed:

"Instructions" hintC [
    "Press W to move forward.",
    "Press S to move backwards.",
    "Use the mouse to turn right or left.",
    "Press V for weapon sights."
];
hintC_EH = findDisplay 72 displayAddEventHandler ["Unload", {
    _this spawn {
        _this select 0 displayRemoveEventHandler ["Unload", hintC_EH];
        hintSilent "";
    };
}];

Example 5

private _separator = parseText "<br/>------------------------<br/>";
private _image = "\ca\ui\textures\aus_flag.paa";
private _message = composeText [image _image, "Heading Text", _separator, "Content"];
"" hintC _message;

See also

hint · hintCadet · hintSilent · BIS_fnc_guiMessage

hintC "foo"; sleep 0.1; hintC "bar"

0 spawn { sleep 0.5; /* your example code goes here*/ };