selectWeapon

Description

Selects the given weapon.

Note

Passing empty string will not deselect current weapon. Use 'SwitchWeapon' action instead:

player action ["SwitchWeapon", player, player, -1]

Syntax

Syntax 1

unitName selectWeapon muzzleName

Parameters:

• unitName: Object

• muzzleName: String - name of the weapon or muzzle

  Important

  For weapons that have more than one muzzle, you have to input the muzzleName and not the weaponName.

  • In Operation Flashpoint, in most cases, both names are the same. But check.
  • In Armed Assault the weaponNames and muzzleNames are different.
  • For muzzle names see CfgWeapons.

Returns: Nothing

Syntax 2

since arma3 2.08

unit selectWeapon [weapon, muzzle, firemode]

Parameters:

• unit: Object - person. This argument has to be local, or it can be remote when executed on the server
• weapon: String - name of the weapon, personal or vehicle's weapon (see weaponState)
• muzzle: String - name of the selected muzzle (see weaponState)
• firemode: String - name of the firemode (see weaponState)

Returns: Boolean or Nothing - true on success, false on failure, Nothing when the call to the command is dispatched over network

Examples

Example 1

_soldier1 selectWeapon "LAWLauncher";

Example 2

player selectWeapon "M203Muzzle";

Example 3

player selectWeapon ["arifle_MX_GL_ACO_F", "arifle_MX_GL_ACO_F", "FullAuto"];

See also

fire · forceWeaponFire · primaryWeapon · handgunWeapon · secondaryWeapon · weapons · ArmA: Actions · isSwitchingWeapon

// Desc: select default weapon & handle multiple muzzles
if (count weapons player > 0) then
{
    private ['_type', '_muzzles'];

    _type = ((weapons player) select 0);
    // check for multiple muzzles (eg: GL)
    _muzzles = getArray (configFile >> "cfgWeapons" >> _type >> "muzzles");

    if (count _muzzles > 1) then
    {
        player selectWeapon (_muzzles select 0);
    }
    else
    {
        player selectWeapon _type;
    };
};

if ((primaryWeapon player) != "") then
{
    private ['_type', '_muzzles'];

    _type = primaryWeapon player;
    // check for multiple muzzles (eg: GL)
    _muzzles = getArray (configFile >> "cfgWeapons" >> _type >> "muzzles");

    if (count _muzzles > 1) then
    {
        player selectWeapon (_muzzles select 0);
    }
    else
    {
        player selectWeapon _type;
    };
};