weaponState

Description

Returns the given or currently selected weapon state for unit or vehicle. With #Syntax 2, if no optional arguments are present, currently selected weapon is queried.

Note

Arma 3: Since Arma 3 v1.70 this command has been improved and extended:

• A vehicle's weapon query doesn't need a weapon operator provided the weapon or muzzle is specified in optional param. (keep in mind that by default a vehicle has no weapons selected)
• Driver turret can now be accessed as well with turret path [-1].
• Muzzle name is supported as well as weapon name. The command searches for weapon first, then if not found, muzzle is searched for.

Syntax

Syntax 1

weaponState unit

Parameters:

• unit: Object

Returns: Array with [weapon, muzzle, firemode, magazine, ammoCount, roundReloadPhase, magazineReloadPhase]

• weapon: String
• muzzle: String
• firemode: String
• magazine: String
• ammoCount: Number
• Arma 3 v2.06 roundReloadPhase: Number in range -1 or 0..1 - current ammo round reload phase (see weaponReloadingTime). -1 when weapon has magazine removed
• Arma 3 v2.06 magazineReloadPhase: Number in range 1..0 - current magazine reload phase, 0 - reload complete. > 0 - reload in progress

Syntax 2

weaponState [vehicle, turretPath, weapon, muzzle, firemode]

Parameters:

• vehicle: Object
• turretPath: Turret Path
• weapon: String - (Optional, default "") weapon or muzzle name (since arma3 1.70)
• muzzle: String - (Optional, default "") muzzle name (since arma3 2.08)
• firemode: String - (Optional, default "") firemode name (since arma3 2.08)

Returns: Array with [weapon, muzzle, firemode, magazine, ammoCount, roundReloadPhase, magazineReloadPhase]

• weapon: String
• muzzle: String
• firemode: String
• magazine: String
• ammoCount: Number
• Arma 3 v2.06 roundReloadPhase: Number - current ammo round reload phase (see weaponReloadingTime)
• Arma 3 v2.06 magazineReloadPhase: Number - current magazine reload phase from 1 to 0, 0 - reload complete. > 0 - reload in progress

Syntax 3

since arma3 2.06

unit weaponState weaponOrMuzzle

Parameters:

• unit: Object
• weaponOrMuzzle: String

Returns: Array with [weapon, muzzle, firemode, magazine, ammoCount, roundReloadPhase, magazineReloadPhase]

• weapon: String
• muzzle: String
• firemode: String
• magazine: String
• ammoCount: Number
• Arma 3 v2.06 roundReloadPhase: Number - current ammo round reload phase (see weaponReloadingTime)
• Arma 3 v2.06 magazineReloadPhase: Number - current magazine reload phase from 1 to 0, 0 - reload complete. > 0 - reload in progress

Examples

Example 1

_wsPlayer = weaponState player;                    // ["arifle_MXC_ACO_F","arifle_MXC_ACO_F","Single","30Rnd_65x39_caseless_mag",30,0,0]

Example 2

Query currently selected gunner weapon:

_wsVehicle = weaponState [_apc, [0]];            // ["autocannon_40mm_CTWS","HE","player","60Rnd_40mm_GPR_Tracer_Red_shells",60,0,0]

Example 3

_wsVehicle = weaponState [_apc, [0], "AP"];        // ["autocannon_40mm_CTWS","AP","player","40Rnd_40mm_APFSDS_Tracer_Red_shells",40,0,0]

Example 4

_wsPlayer = player weaponState "GL_3GL_F";        // ["arifle_MX_GL_ACO_F","GL_3GL_F","Single","1Rnd_HE_Grenade_shell",1,0,0]

See also

weapons · selectWeaponTurret · loadMagazine · magazinesTurret · weaponsTurret · weaponReloadingTime

player selectWeapon "GL_3GL_F";
_state = player weaponState "arifle_MX_GL_ACO_F";    // ["arifle_MX_GL_ACO_F","GL_3GL_F","Single","1Rnd_HE_Grenade_shell",1,0,0]
_state = player weaponState "GL_3GL_F";                // ["arifle_MX_GL_ACO_F","GL_3GL_F","Single","1Rnd_HE_Grenade_shell",1,0,0]

player selectWeapon "arifle_MX_GL_ACO_F";
_state = player weaponState "arifle_MX_GL_ACO_F";    // ["arifle_MX_GL_ACO_F","arifle_MX_GL_ACO_F","Single","30Rnd_65x39_caseless_mag",30,0,0]
_state = player weaponState "GL_3GL_F";                // ["arifle_MX_GL_ACO_F","GL_3GL_F","Single","1Rnd_HE_Grenade_shell",1,0,0]

fn_getWeaponStates =
{
    params ["_unit", "_weapon"];
    private _origState = weaponState _unit select [0,3];
    private _muzzles = [_weapon] + (getArray (configFile >> "CfgWeapons" >> _weapon >> "muzzles") select { _x != "this" });
    private _states = [];

    {
        _unit selectWeapon _x;
        _states pushBack weaponState _unit;
    } forEach _muzzles;

    _unit selectWeapon _origState;
    _states;
};

private _result = [player, primaryWeapon player] call fn_getWeaponStates;
/*
    [
        ["arifle_MX_GL_ACO_F", "arifle_MX_GL_ACO_F", "Single", "30Rnd_65x39_caseless_mag", 30, 0, 0],
        ["arifle_MX_GL_ACO_F", "GL_3GL_F", "Single", "1Rnd_HE_Grenade_shell", 1, 0, 0]
    ]
*/