setPlayerRespawnTime

Description

Sets the time interval (in seconds) that the player must wait before respawn, for the next respawn only. It resets to mission default on mission start. In Single Player or when respawn type is GROUP or SIDE in Multiplayer, setting player respawn time has no effect, and playerRespawnTime will always return -1.

Syntax

setPlayerRespawnTime interval

Parameters:

interval: Number - respawn time in seconds

Returns: Nothing

Examples

Example 1

setPlayerRespawnTime 5; // next respawn (and only this one) will happen 5s after death

Example 2

Set the respawn duration through variable:

player addEventHandler ["Killed", {
    setPlayerRespawnTime (player getVariable ["TAG_RespawnDelay", 10]);
}];

Somewhere else, e.g on objective completion:

player setVariable ["TAG_RespawnDelay", 5];

or if that player is on another machine:

waitUntil { not alive _target };
_thatPlayer setVariable ["TAG_RespawnDelay", 5, true];

Example 3

Increase respawn duration every death:

player addEventHandler ["Killed", {
    private _respawnTime = player getVariable ["TAG_RespawnDelay", 8];
    setPlayerRespawnTime _respawnTime;
    player setVariable ["TAG_RespawnDelay", _respawnTime + 1]; // don't die too many times
}];