setVariable

Description

Set variable to given value in the variable space of given element. Can be used to broadcast variables over the network.

To remove a variable, set it to nil (see #Example 5) - note that this does not work on Object and scripted Location namespaces (the variable will be set to nil but will remain listed by allVariables).

Warning

missionNamespace, uiNamespace, parsingNamespace and profileNamespace variables cannot be named as commands - e.g missionNamespace setVariable ["west", 123]; conflicts with the west command and will result in a Reserved variable in expression error, west being a scripting command (other namespaces do not have such limitation). See also all available script commands.

Syntax

varspace setVariable [name, value, public]

Parameters:

• varspace: variable space in which variable can be set. Can be one of:

  • Namespace
  • Object
    • ✓ Arma 3 v2.10 CfgAmmo Objects (bullets, mines etc)
    • ✗ CfgNonAIVehicles Objects (butterflies, proxies etc - EmptyDetectors (triggers) work)
    • ✗ 1. local Objects (1. lightpoint, 1. soundsource etc - see createVehicleLocal)
  • Group
  • Location (Arma 3 v2.10 scripted ones only)
  • Arma 2 v1.00 Team Member
  • Arma 2 v1.00 Task - value will actually be set on the Task's FSM if it exists.
  • Arma 3 v0.50 Control
  • Arma 3 v0.50 Display

• name: String - variable name (Identifier)

• value: Anything - variable value

• public - (Optional, default false) can be one of:

  • Boolean - if set to true, the variable is broadcast globally and is persistent (JIP compatible) Global Effect
  • Number - the variable is only set on the client with the given Machine network ID. If the number is negative, the variable is set on every client except for the one with the given ID.
  • Array of Numbers - array of Machine network IDs

  This parameter is only available if the varspace parameter is a Namespace, Object or Group. Furthermore, only the following Data Types can be broadcast:

  Type	Number	Boolean	Object	Group	String	Text	Array	Code	Nothing (nil)	HashMap
  Since	Armed Assault v1.00	Armed Assault v1.09	Arma 3 v1.26	Arma 3 v2.02

Returns: Nothing

Examples

Example 1

_myTruck setVariable ["TAG_myPublicVariable", 123, true];

Example 2

_myTruck setVariable ["TAG_myLocalVariable", ["321", _var], owner driver _myTruck];

Example 3

missionNamespace setVariable ["TAG_myName", "Brian"];
hint TAG_myName; // hints "Brian"

Example 4

Get the current value of a variable or, if it is undefined, define it and then get the value:

private _var = missionNamespace getVariable "VarName";
if (isNil "_var") then
{
    _var = 123;
    missionNamespace setVariable ["VarName", _var];
};
// _var now contains the current value of the missionNamespace's variable varName

Example 5

Remove TAG_myPublicVariable from missionNamespace (globally):

missionNamespace setVariable ["TAG_myPublicVariable", nil, true];

See also

getVariable · allVariables · setFSMVariable