BIS_fnc_strategicMapOpen

Description

Creates a strategic map.

Syntax

[display, pos, missions, ORBATs, markers, images, weather, night, scale, simulation, label, missionName, missionIcon] call BIS_fnc_strategicMapOpen

Parameters:

• display: Display - parent display. When empty, mission display is used.
• pos: Array format Position - default view position in format [x,y,y] or [x,y]
• missions: Array - list of missions, each Array in format:
  • 0: Position - 2D or 3D position of mission
  • 1: Code - Expression executed when user clicks on mission icon
  • 2: String - Mission name
  • 3: String - Short description
  • 4: String - Name of mission's player
  • 5: String - Path to overview image
  • 6: Number - size multiplier for overview image
  • 7: Array - parameters for on-click action. Can be accessed in code with _this # 9
• ORBATs: Array - list of ORBAT, each Array in format:
  • 0: Array format Position - 2D or 3D position
  • 1: Config - preview CfgORBAT group
  • 2: Config - topmost displayed CfgORBAT group
  • 3: Array of Strings - list of allowed tags
  • 4: String - name of mission's player
  • 5: Number - maximum number of displayed tiers
• markers: Array of Strings - list of markers revealed in strategic map (will be hidden when map is closed)
• images: Array - list of custom images, each Array in format:
  • 0: String - texture path
  • 1: Array format Color (RGBA)
  • 2: Array format Position - image position
  • 3: Number - image width in meters
  • 4: Number - image height in meters
  • 5: Number - image angle in degrees
  • 6: String - text displayed next to the image
  • 7: Boolean - true to show shadow
• weather: Number - overcast, from 0 - 1, where 1 means cloudy weather
• night: Boolean - true for night version of strategic map (darker with blue tone)
• scale: Number - default map scale coeficient (1 is automatic scale)
• simulation: Boolean] - (Optional, default false true to enable simulation while the map is opened
• label: String - (Optional, default "Select a mission") bottom bar action label text
• missionName: Boolean - (Optional, default true) true to show icon label as a mission name
• missionIcon: String - (Optional, default "\A3\Ui_f\data\Map\GroupIcons\badge_rotate_%1_gs.paa") path to mission icon texture
  • %1 - Animation frame from 0-6 (optional)
  • %2 - Index from 1-9 (optional)

Returns: Display - rscDisplayStrategicMap

Examples

Example 1

[
    findDisplay 46,
    [2000,2000,0],
    [
        [
            [2000,2000,0],
            {systemChat format ["%1",name ((_this # 9) # 0)]},
            "1st Mission",
            "This is mission one",
            "Name of mission's player",
            "\A3\Data_F_Exp\Logos\arma3_exp_icon_ca.paa",
            1.5,
            [player]
        ],
        [
            [1000,1000,0],
            {systemChat format ["%1",name ((_this # 9) # 0)]},
            "2nd Mission",
            "This is mission two",
            "Name of mission's player",
            "\A3\Data_F_Argo\Logos\arma3_argo_logoTitle_ca.paa",
            1.5,
            [player]
        ]
    ],
    [
        [
            [3000,3000,0],
            configFile >> "CfgORBAT" >> "BIS" >> "B_1_A_1_2",
            configFile >> "CfgORBAT" >> "BIS" >> "B_1",
            [],
            10
        ]
    ],
    [
        "marker_1",
        "marker_2"
    ],
    [
        [
            "\A3\Ui_f\data\Logos\arma3_white_ca.paa",
            [0,0,0,1],
            [4000,4000,0],
            8,
            8,
            0,
            "Arma 3 Logo",
            true
        ]
    ],
    0,
    false,
    1,
    true,
    "Strategic Map Example",
    false,
    "\A3\Ui_f\data\Logos\arma3_white_ca.paa"
] call BIS_fnc_strategicMapOpen;

See also

ORBAT Viewer · BIS_fnc_ORBATAddGroupOverlay · BIS_fnc_ORBATAnimate · BIS_fnc_ORBATConfigPreview · BIS_fnc_ORBATGetGroupParams · BIS_fnc_ORBATOpen · BIS_fnc_ORBATRemoveGroupOverlay · BIS_fnc_ORBATSetGroupFade · BIS_fnc_ORBATSetGroupParams · BIS_fnc_ORBATTooltip · BIS_fnc_strategicMapMouseButtonClick · BIS_fnc_strategicMapAnimate

"images\MyImage.jpg" // Does not work
([str missionConfigFile, 0, -15] call BIS_fnc_trimString) + "images\MyImage.jpg" // works

// edit: since Arma 3 v1.96 getMissionPath is available
getMissionPath "images\MyImage.jpg" // works

waitUntil { !isNull findDisplay 46 };

private _position = getPosWorld mission1;
_position2d = [_position select 0, _position select 1];
_missions pushBack [
    _position2d,
    { /*mission code*/ },
    "My mission",
    "My mission description"
];