addAction

Description

Adds an entry to the action menu of an object. The action can only be activated when in proximity to the object and looking at it. Adding an action to the player makes that action available to the player at all times. For event handling of user interaction see inGameUISetEventHandler.

Syntax

object addAction [title, script, arguments, priority, showWindow, hideOnUse, shortcut, condition, radius, unconscious, selection, memoryPoint]

Parameters:

• object: Object - unit, vehicle or static object. No agents and simple objects!

• title: String - the action name displayed in the action menu, may contain Structured Text. Because of that < and > symbols will be interpreted as opening and closing XML tags. To avoid this use < for < and > for >. The title text appearance can be changed with setUserActionText

• script: String or Code - either path to the script file, relative to the mission folder or string with code or the actual script code. If the string is a path to script file, the script file must have extension .SQS or .SQF. The script, whether it is a file or a code, will run in scheduled environment, i.e. it is ok to use sleep. Parameters array passed to the script upon activation in _this variable is:

  params ["_target", "_caller", "_actionId", "_arguments"];
  

  • target: Object - the object which the action is assigned to
  • caller: Object - the unit that activated the action
  • actionID: Number - activated action's ID (same as addAction's return value)
  • arguments: Anything - arguments given to the script if you are using the extended syntax

• arguments: Anything - (Optional, default nil) arguments to pass to the script. Accessible with _this select 3 inside the script. If Array is used as an argument for example, its first element reference would be _this select 3 select 0

• priority: Number - (Optional, default 1.5) priority value of the action. Actions will be arranged in descending order according to this value. Every game action has a preset priority value. Value can be negative or decimal fraction. Actions with same values will be arranged in order which they were made, newest at the bottom. The bigger the number the higher the action will be positioned on the menu. Typical range is 0 to 6

• showWindow: Boolean - (Optional, default true) if set to true, players see "Titletext" at mid-lower screen, as they approach the object. Only the title text for the action with highest priority and showWindow set to true will be shown

• hideOnUse: Boolean - (Optional, default true) if set to true, it will hide the action menu after selecting it. If set to false, it will leave the action menu open and visible after selecting the action, leaving the same action highlighted, for the purpose of allowing you to re-select that same action quickly, or to select another action

• shortcut: String - (Optional, default "") one of the key names defined in bin.pbo (e.g. "moveForward"). Adding available shortcut will bind corresponding keyboard key to this action. Shortcut availability can be tested with inputAction command

• condition: String - (Optional, default "true") expression that must return true for the action to be shown. Special variables passed to the script code are:

  • _target: Object - The object to which action is attached or, if the object is a unit inside of vehicle, the vehicle
  • _this: Object - Caller person to whom the action is shown (or not shown if condition returns false)
  • _originalTarget: Object - The original object to which the action is attached, regardless if the object/unit is in a vehicle or not
  • _actionId: Number - checked action's ID (same as addAction's return value)

  Warning

  If the player is the group leader, has an action added to them, and selects a subordinate, *_this* alternatively switches between the player and this selected unit - RPT logging Unknown attribute itemsCmd in the process.

  Important

  • condition is evaluated on each frame in unscheduled environment.
  • condition is not evaluated if a dialog is open.
  • If action is added to an object and not to the player, condition will only get evaluated if the player is closer than ~50m to the object surface and is looking at the object.
  • If action is added to player, condition is evaluated all the time.

• radius: Number - (Optional, default 50) maximum 3D distance in meters between the activating unit's eyePos and object**s memoryPoint*,* selection or position. -1 disables the radius; hardcoded limit is* 50*' (since arma3 1.64)

• unconscious: Boolean - (Optional, default false) if true will be shown to incapacitated player. See also setUnconscious and lifeState (since arma3 1.64)

• selection: String - (Optional, default "") object's geometry LOD's named selection (since arma3 1.70)

• memoryPoint: String - (Optional, default "") object's memory point. If selection is supplied, memoryPoint is not used (since arma3 1.82)

Returns: Number - the added action's ID. Action can be removed with removeAction (see also removeAllActions). IDs are incrementing, the first given action to each unit has the ID 0, the second the ID 1, etc. IDs are also passed to the called script (see the script parameter)

Examples

Example 1

// short and sweet
player addAction ["a useless action that does nothing", {}];
player addAction ["<t color='#FF0000'>This Useless Action Is RED</t>", { hint "RED" }];
player addAction ["Hint Hello!", { hint format ["Hello %1!", name player] }];
player addAction ["String Exec", "hint 'this is also compiled'"];

Example 2

_actionID = player addAction ["Exec the file", "scriptFile.sqf"];

scriptFile.sqf:

hint str _this;

Example 3

// create object on the server and add action to the object on every client
if (isServer) then
{
    private _object = "some_obj_class" createVehicle [1234, 1234, 0];
    [_object, ["Greetings!", { hint "Hello!"; }]] remoteExec ["addAction"]; // Note: does not return action id
};

Example 4

Default parameters:

this addAction
[
    "title",
    {
        params ["_target", "_caller", "_actionId", "_arguments"];
    },
    nil,
    1.5,
    true,
    true,
    "",
    "true",
    50,
    false,
    "",
    ""
];

Example 5

Default parameters with comments:

this addAction
[
    "title",    // title
    {
        params ["_target", "_caller", "_actionId", "_arguments"]; // script
    },
    nil,        // arguments
    1.5,        // priority
    true,        // showWindow
    true,        // hideOnUse
    "",            // shortcut
    "true",        // condition
    50,            // radius
    false,        // unconscious
    "",            // selection
    ""            // memoryPoint
];

Multiplayer

The command will be ignored on dedicated servers, probably because no UI exists.

See also

actionIDs · actionParams · setUserActionText · inGameUISetEventHandler · showHUD · inputAction · removeAction · removeAllActions · action · shownAction · BIS_fnc_holdActionAdd

private _actionId = player addAction ["Heal", {}];
player setUserActionText [_actionId, "Heal", "<img size='2' image='\a3\ui_f\data\IGUI\Cfg\Actions\heal_ca'/>"];

_obj addAction ["Test", "path\script.sqf"]; // "path\script.sqf" won't execute

_obj addAction ["Test", { _this spawn compile preprocessFileLineNumbers "path\script.sqf" }];