setMissileTargetPos

Description

Sets a guided munition target position. The munition must have manualControl config entry to use this command. The target position has to be inside the missile's configured targeting cone for the command to work.

Syntax

munition setMissileTargetPos position

Parameters:

munition: Object
position: PositionATL

Returns: Nothing

Examples

Example 1

missile1 setMissileTargetPos unitAimPosition tank1;

Example 2

private _missile = createVehicle ["M_Scalpel_AT", player modelToWorld [0,0,100], [], 0, "CAN_COLLIDE"];
_missile setMissileTargetPos (player modelToWorld [0,100,0]);

Community notes

Benargee2020-04-13

To get list of compatible missiles with manualControl = 1, use the below script and paste the clipboard results to a text editor.

private _cfgCount = count (configfile >> "CfgAmmo");
private _pasteStr = "";

for "_x" from 0 to (_cfgCount - 1) do {
    _cfg = (configFile >> "CfgAmmo") select _x;
    _ammoClassName = configName _cfg;
    private _manCtrl = getNumber (configFile >> "CfgAmmo" >> _ammoClassName >> "manualControl");
    if (_manCtrl > 0) then {
            _pasteStr = _pasteStr + _ammoClassName + endl;
    };
};

copyToClipboard _pasteStr;

Lou Montana2022-08-12

Tested with a player-controlled AH-99 firing DAGR, a civilian helicopter named heli above water/land, and the following code:

if (!isNil "EH") then
{
    vehicle player removeEventHandler ["Fired", EH];
};
EH = vehicle player addEventHandler ["Fired", {
params ["_unit", "_weapon", "_muzzle", "_mode", "_ammo", "_magazine", "_missile", "_gunner"];
    _missile setMissileTargetPos getPosATL heli; // changing here getPosATL / getPosASL / getPos
    systemChat str [_missile, missileTarget _missile, missileTargetPos _missile];
}];