setRain

Description

Sets rain density smoothly over the given transition time. A transition time of zero means an immediate change. A rain density of zero is no rain, one is maximum rain. Rain is not possible when overcast is less than 0.7.

Note

Arma 3: Since Arma 3 this command is multiplayer-synchronised:

• if executed on the server, the changes will propagate globally.
• if executed on a client, the effect is local, temporary and will soon change to the server setting. Minimum overcast needed for rain in Arma 3 is 0.5.

Important

Alternative syntaxes (#Syntax 2 and #Syntax 3):

• set rain particle params. Rain particles params are client-side params and are ignored on dedicated server. Use helper function BIS_fnc_setRain if sync is needed in Multiplayer
• have a local Local Effect effect

Syntax

Syntax 1

time setRain rain

Parameters:

• time: Number - transition time in seconds to the new value
• rain: Number in range 0..1 - new rain value

Returns: Nothing

Syntax 2

since arma3 2.08 · effect: local

setRain rainParams

Parameters:

• rainParams: Array of Anything - custom RainParticles params - see rainParams. Use empty array [] to reset to default config values

Returns: Nothing

Syntax 3

since arma3 2.08 · effect: local

setRain config

Parameters:

• config: Config - config path to a custom class, which contains RainParticles class. Use configNull to reset to default config values

Returns: Nothing

Examples

Example 1

60 setRain 1;

Example 2

Force no rain:

0 setRain 0;
forceWeatherChange;
999999 setRain 0;

Example 3

See also BIS_fnc_setRain since Arma 3 v2.10:

0 setOvercast 1;
0 setRain 1;
0 setFog 0.1;        // snow affects visibility at distance
setHumidity 0.9;    // don't want to see dust clouds
enableEnvironment [false, true];    // don't want to see snakes and butterflies either
forceWeatherChange;
[
    "a3\data_f\snowflake4_ca.paa",    // rainDropTexture - 4 means it has 4 flakes in it. Other available textures: snowflake8_ca.paa, snowflake16_ca.paa
    4,                // texDropCount - 4 because we are using texture with 4 flakes. Change to 8 or 16 in accordance with other textures used
    0.01,            // minRainDensity
    25,                // effectRadius
    0.05,            // windCoef
    2.5,            // dropSpeed
    0.5,            // rndSpeed
    0.5,            // rndDir
    0.07,            // dropWidth
    0.07,            // dropHeight
    [1, 1, 1, 0.5],    // dropColor
    0.0,            // lumSunFront
    0.2,            // lumSunBack
    0.5,            // refractCoef
    0.5,            // refractSaturation
    true,            // snow
    false            // dropColorStrong
]
call BIS_fnc_setRain;

Multiplayer

Prior to Arma 3, each client and the server could have different rain values.

See also

rainParams · BIS_fnc_setRain · overcast · setOvercast · rain · nextWeatherChange · forceWeatherChange · setFog · setHumidity

skipTime 1; skipTime -1;