remoteExecutedJIPID

Description

Returns JIP ID of the persistent call generated from JIP queue for the joining player (see remoteExec).

Syntax

remoteExecutedJIPID

Returns: String - JIP ID

Examples

Example 1

_jipid = remoteExecutedJIPID;

Example 2

/* 
Have mission with 2 players.
First player starts local server and executes given code
Second player joins the server and sees the 'all good' message
Second player logs out 
First player kills 'bob'
Second player joins back and sees 'removing JIP call' message
Second player logs out then joins back in, no message as call was removed
*/

private _fnc = 
{
    if (isRemoteExecutedJIP) then
    {
        remoteExecutedJIPID splitString "|" params ["_myID", "_netID"];
        private _obj = objectFromNetId _netID;
        if (!alive _obj) then
        {
            hint "object is dead or deleted, removing JIP call";
            remoteExec ["", remoteExecutedJIPID];
        }
        else
        {
            hint "JIP call, all good, doing something";
        };
    };
};

private _bob = group player createUnit [typeOf player, position player, [], 0, "NONE"];
private _myID = "lalala";
private _jipID = [_myID, netId _bob] joinString "|";
[[], _fnc] remoteExec ["call", 0, _jipId];

See also

remoteExecutedOwner · isRemoteExecuted · isRemoteExecutedJIP · remoteExec · remoteExecCall · canSuspend · publicVariableClient · admin · owner · clientOwner · groupOwner · didJIPOwner