BIS_fnc_packStaticWeapon

Arma 3 v1.00

Function · Markdown · JSON · original wiki page

Description

This function will make weapon team pack a static weapon. The weapon crew will pack carried weapon (or given weapon if different) and follow leader. Requires three personnel in the team: Team Leader, Gunner and Asst. Gunner. This function is MP compatible

When the weapon is packed, scripted EH "StaticWeaponPacked" is called with the following params:

[group, leader, gunner, assistant, weaponBag, tripodBag]

Note
If a unit flees, all bets are off and the function will exit leaving units on their own. To guarantee weapon disassembly, make sure the group has maximum courage
_group allowFleeing 0;

Syntax

[group, weapon, leaderPos] call BIS_fnc_packStaticWeapon

Parameters:

group: Group or Object - the support team group or a unit from this group
weapon: Object - (Optional) weapon to pack. If nil, current group weapon is packed
leaderPos: Array, String or Object - (Optional) position, object or marker to which the group leader should move after the weapon is packed. By default the group will resume on to the next assigned waypoint. If this param is provided, group will not go to the next waypoint and will move to given position instead

Returns: Nothing

Examples

Example 1

[leader1] call BIS_fnc_packStaticWeapon;

Example 2

group1 allowFleeing 0;
[group1, nil, "leaderpos_marker"] call BIS_fnc_packStaticWeapon;

Community notes

Killzone_Kid

2017-01-06

The following script will create a group consisting of a Team Leader, Gunner and Asst. Gunner and give the group 2 random MOVE waypoints. After the group reached the 1st waypoint, waypoint statement will execute BIS_fnc_unpackStaticWeapon and the group will stop and unpack static weapon, while leader is given random position to go to. After 7 seconds the BIS_fnc_packStaticWeapon is executed and the group packs and heads to 2nd waypoint.

private _group = createGroup west;
private _pos = player getRelPos [20, 0];
private _randomDir = random 360;
private _wp1 = _group addWaypoint [_pos getPos [20, _randomDir], 10];
_wp1 setWaypointType "MOVE";
_wp1 setWaypointStatements ["true", "
    group this allowFleeing 0;
    [group this, 'StaticWeaponUnpacked', {
        _this spawn
        {
            sleep 7;
            [_this select 0] call BIS_fnc_packStaticWeapon;
        };
    }] call BIS_fnc_addScriptedEventHandler;
    [
        this,
        this,
        this getPos [1000, random 360],
        this getPos [10, 0]
    ] call BIS_fnc_unpackStaticWeapon;
"];
private _wp2 = _group addWaypoint [_pos getPos [20, _randomDir - 180], 10];
_wp2 setWaypointType "MOVE";
private _leader = _group createUnit ["B_Soldier_TL_F", _pos, [], 0, "NONE"];
private _gunner = _group createUnit ["B_Support_GMG_F", _pos, [], 0, "NONE"];
private _assistant = _group createUnit ["B_Support_AMG_F", _pos, [], 0, "NONE"];
units _group doFollow _leader;