BIS_fnc_createTooltip

Description

Shows group tooltip. Adapted for Tac Ops DLC for use in the animated briefings.

Syntax

[input, display, mousePos] call BIS_fnc_createTooltip

Parameters:

• input: Array format [config, parameters]:
  • config: Config - group from CfgORBAT
  • parameters: Array - group params returned by BIS_fnc_ORBATGetGroupParams
• display: Display - display where tooltip controls group is created
• mousePos: Array - mouse position in format [x, y]

Returns: Boolean

Examples

Example 1

// enable icons in 2D and 3D
setGroupIconsVisible [true, true];
setGroupIconsSelectable true;

// add the icon for all existing groups
private _group = group player;
private _color = [side _group, false] call BIS_fnc_sideColor;
_group addGroupIcon ["o_inf", [0, 0]];
_group setGroupIconParams [_color, groupID _group, 1, true];

// show tooltip when hovering over group icon of player group
addMissionEventHandler ["GroupIconOverEnter",
{
    [configFile >> "CfgORBAT" >> "BIS" >> "I_AAF", findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
}];

// remove tooltip when leaving group icon area
addMissionEventHandler ["GroupIconOverLeave",
{
    [nil, findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
}];

Example 2

private _marker = createMarker ["marker_0", [worldSize / 2, worldSize / 2]];
_marker setMarkerType "flag_Germany";
_marker setMarkerText "GERMANY";

_marker = createMarker ["marker_1", [worldSize / 1.5, worldSize / 1.5]];
_marker setMarkerType "flag_Altis";
_marker setMarkerText "ALTIS";

findDisplay 12 displayCtrl 51 ctrlAddEventHandler
[
    "draw",
    {
        params ["_ctrlMap"];

        ctrlMapMouseOver _ctrlMap params [["_type", ""], ["_markerName", ""]];

        if (_type == "marker") then
        {
            private _markerTexture = getText (configFile >> "CfgMarkers" >> markerType _markerName >> "icon");
            private _markerText = markerText _markerName;

            [[nil, nil, _markerName, nil, _markerTexture, nil, nil, nil, _markerText, nil, nil, "Some Description"], findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
        }
        else
        {
            [nil, findDisplay 12, getMousePosition] call BIS_fnc_createTooltip;
        };
    }
];

See also

BIS_fnc_ORBATGetGroupParams